[Unity] Shader(着色器）输入输出和语义

Shader "Sbin/sf" {
    Properties {
        // 颜色值
        _Color ("Color", Color) = (1,1,1,1)
        // 主纹理
        _MainTex ("Albedo (RGB)", 2D) = "white" {}
        // 高光光泽度
        _Glossiness ("Smoothness", Range(0,1)) = 0.5
        // 材质金属光泽
        _Metallic ("Metallic", Range(0,1)) = 0.0
    }

    // 在surfaceShader不需要有Pass通道，否则会报错
    SubShader {
        // 渲染类型，是一个不透明物体
        //Tags { "RenderType"="Opaque" }
        Tags { "RenderType"="Opaque" "Queue" = "Transparent" }
        // 层级细节
        LOD 200

        // 代码块，表示从这一句下面开始直到EndCG，表示我们是使用了CG语言编写的代码
        CGPROGRAM

        // #pragma 编译指令 
        // 格式： 
        // #pragma surface surfaceFunction lightModel [optionalparams]
        // #pargma 关键词 函数名 光照模型 [其它选项]

        // Physically based Standard lighting model, and enable shadows on all light types
        //#pragma surface surf Standard fullforwardshadows
        //#pragma surface surf Lambert 
        //#pragma surface surf Lambert alpha
        #pragma surface surf Lambert addshadow


        // 使用model 3.0 可以得到一个更好的光照效果， 默认是2.0
        // Use shader model 3.0 target, to get nicer looking lighting
        #pragma target 3.0

        // 如果在Properties使用2D，CG里要用sampler2D，代表使用的是2维纹理
        // 如果在Properties使用color, CG里要用fixed4
        // 如果在Properties使用Range, CG里要用half，实际上描述的是一个float
        sampler2D _MainTex;

        // 输入结构体用于模述UV的坐标。
        struct Input {
            // 变量必须是uv_开头，_号后面的_MainTex自动对应Properties中的_MainTex和sampler2D
            // _MainTex 也是不能变的。
            float2 uv_MainTex;
        };

//        half _Glossiness;
//        half _Metallic;
//        fixed4 _Color;

        // in 参数是输入的
        // out 参数是输出的
        // inout 参数即是输入，又是输出
        // SurfaceOutputStandard 可以使用基于物理的光照模型(次时代)
        //void surf (Input IN, inout SurfaceOutputStandard o) {
        void surf (Input IN, inout SurfaceOutput o) {
            // Albedo comes from a texture tinted by color
            // 从纹理中进行采样
            //fixed4 c = tex2D (_MainTex, IN.uv_MainTex) * _Color;
            fixed4 c = tex2D (_MainTex, IN.uv_MainTex);  
            o.Albedo = c.rgb; // 基本的漫反射
            // Metallic and smoothness come from slider variables
            //o.Metallic = _Metallic;
            //o.Smoothness = _Glossiness;
            o.Alpha = c.a; // 透明度
        }
        ENDCG
    }
    // FallBack 当我们的surfaceshader编译后没有一个阴影通道时，会自动添加一个阴影通道
    //FallBack "Diffuse"
}

Shader "Example/Diffuse Simple" {
    SubShader {
      Tags { "RenderType" = "Opaque" }
      CGPROGRAM
      #pragma surface surf Lambert
      struct Input {
          float4 color : COLOR;
      };
      void surf (Input IN, inout SurfaceOutput o) {
          o.Albedo = 1;
      }
      ENDCG
    }
    Fallback "Diffuse"
  }

Shader "Example/Diffuse Texture" {
    Properties {
      _MainTex ("Texture", 2D) = "white" {}
    }
    SubShader {
      Tags { "RenderType" = "Opaque" }
      CGPROGRAM
      #pragma surface surf Lambert
      struct Input {
          float2 uv_MainTex;
      };
      sampler2D _MainTex;
      void surf (Input IN, inout SurfaceOutput o) {
          o.Albedo = tex2D (_MainTex, IN.uv_MainTex).rgb;
      }
      ENDCG
    } 
    Fallback "Diffuse"
  }

Shader "Example/Diffuse Bump" {
    Properties {
      _MainTex ("Texture", 2D) = "white" {}
      _BumpMap ("Bumpmap", 2D) = "bump" {}
    }
    SubShader {
      Tags { "RenderType" = "Opaque" }
      CGPROGRAM
      #pragma surface surf Lambert
      struct Input {
        float2 uv_MainTex;
        float2 uv_BumpMap;
      };
      sampler2D _MainTex;
      sampler2D _BumpMap;
      void surf (Input IN, inout SurfaceOutput o) {
        o.Albedo = tex2D (_MainTex, IN.uv_MainTex).rgb;
        o.Normal = UnpackNormal (tex2D (_BumpMap, IN.uv_BumpMap));
      }
      ENDCG
    } 
    Fallback "Diffuse"
  }

Shader "Example/Rim" {
    Properties {
      _MainTex ("Texture", 2D) = "white" {}
      _BumpMap ("Bumpmap", 2D) = "bump" {}
      _RimColor ("Rim Color", Color) = (0.26,0.19,0.16,0.0)
      _RimPower ("Rim Power", Range(0.5,8.0)) = 3.0
    }
    SubShader {
      Tags { "RenderType" = "Opaque" }
      CGPROGRAM
      #pragma surface surf Lambert
      struct Input {
          float2 uv_MainTex;
          float2 uv_BumpMap;
          float3 viewDir;
      };
      sampler2D _MainTex;
      sampler2D _BumpMap;
      float4 _RimColor;
      float _RimPower;
      void surf (Input IN, inout SurfaceOutput o) {
          o.Albedo = tex2D (_MainTex, IN.uv_MainTex).rgb;
          o.Normal = UnpackNormal (tex2D (_BumpMap, IN.uv_BumpMap));
          half rim = 1.0 - saturate(dot (normalize(IN.viewDir), o.Normal));
          o.Emission = _RimColor.rgb * pow (rim, _RimPower);
      }
      ENDCG
    } 
    Fallback "Diffuse"
  }