Linux异常体系之stubs_offset

标签：处理器   sys   svc   http   跳转   ida   obj   设定   一个   

转自 http://www.xuebuyuan.com/2208550.html

在ARM V4及V4T以后的大部分处理器中，中断向量表的位置可以有两个位置：一个是0x00000000，另一个是0xffff0000。可以通过CP15协处理器c1寄存器中V位(bit[13])控制。V和中断向量表的对应关系如下：

        V=0        ～        0x00000000~0x0000001C

        V=1        ～        0xffff0000~0xffff001C

在arch/arm/mm/proc-arm920.S中：

    .type   __arm920_setup, #function
__arm920_setup:
    mov r0, #0
    mcr p15, 0, r0, c7, c7      @ invalidate I,D caches on v4
    mcr p15, 0, r0, c7, c10, 4      @ drain write buffer on v4
#ifdef CONFIG_MMU
    mcr p15, 0, r0, c8, c7      @ invalidate I,D TLBs on v4
#endif
    adr r5, arm920_crval
    ldmia   r5, {r5, r6}
    mrc p15, 0, r0, c1, c0      @ get control register v4
    bic r0, r0, r5
    orr r0, r0, r6
    mov pc, lr
    .size   __arm920_setup, . - __arm920_setup
   
    /*
    ┊*  R
    ┊* .RVI ZFRS BLDP WCAM
    ┊* ..11 0001 ..11 0101
    ┊* 
    ┊*/
    .type   arm920_crval, #object
arm920_crval:
    crval   clear=0x00003f3f, mmuset=0x00003135, ucset=0x00001130

V(bit13)=1，中断向量表基址为0xFFFF0000。

在linux中，向量表建立的函数为：

init/main.c --> start_kernel() --> trap_init()。

void __init trap_init(void)
{

    unsigned long vectors = CONFIG_VECTORS_BASE;
    ...
    memcpy((void *)vectors, __vectors_start, __vectors_end - __vectors_start);
    memcpy((void *)vectors + 0x200, __stubs_start, __stubs_end - __stubs_start);
    ...

}

在2.6.26内核中CONFIG_VECTORS_BASE最初是在各个平台的配置文件中设定的，如arch/arm/configs/s3c2410_defconfig中：

CONFIG_VECTORS_BASE=0xffff0000

__vectors_end 至 __vectors_start之间为异常向量表，位于arch/arm/kernel/entry-armv.S中：

    .globl  __vectors_start
__vectors_start:
 ARM(   swi SYS_ERROR0  )
 THUMB( svc #0      )
 THUMB( nop         )    
    W(b)    vector_und + stubs_offset
    W(ldr)  pc, .LCvswi + stubs_offset
    W(b)    vector_pabt + stubs_offset
    W(b)    vector_dabt + stubs_offset
    W(b)    vector_addrexcptn + stubs_offset
    W(b)    vector_irq + stubs_offset
    W(b)    vector_fiq + stubs_offset
             
    .globl  __vectors_end
__vectors_end:

__stubs_end 至 __stubs_start之间是异常处理的位置。也位于文件arch/arm/kernel/entry-armv.S中。vector_und、vector_pabt、vector_irq、vector_fiq都在它们中间。

stubs_offset值：.equ    stubs_offset, __vectors_start + 0x200 - __stubs_start

当汇编器看到B指令后会把要跳转的标签转化为相对于当前PC的偏移量（±32M）写入指令码。从上面的代码可以看到中断向量表和stubs都发生了代码搬移，所以如果中断向量表中仍然写成b vector_irq，那么实际执行的时候就无法跳转到搬移后的vector_irq处，因为指令码里写的是原来的偏移量，所以需要把指令码中的偏移量写成搬移后的。我们把搬移前的中断向量表中的irq入口地址记irq_PC,它在中断向量表的偏移量就是irq_PC-vectors_start, vector_irq在stubs中的偏移量是vector_irq-stubs_start，这两个偏移量在搬移前后是不变的。搬移后 vectors_start在0xffff0000处，而stubs_start在0xffff0200处，所以搬移后的vector_irq相对于中断 向量中的中断入口地址的偏移量就是

    200+(vector_irq-stubs_start)-(irq_PC-vectors_star) = (vector_irq-irq_PC) + vectors_start+200-stubs_start

对于括号内的值实际上就是中断向量表中写的vector_irq，减去irq_PC是由汇编器完成的，而后面的 vectors_start+200-stubs_start就应该是stubs_offset，实际上在entry-armv.S中也是这样定义的。

Linux异常体系之stubs_offset

标签：处理器   sys   svc   http   跳转   ida   obj   设定   一个   

原文地址：http://www.cnblogs.com/yangjiguang/p/7630055.html