SqlServer 分区视图实现水平分表

USE [DemoDB]  
GO  
  
--  创建结构相同的表，[id] 不要设置自增（IDENTITY(1,1) ），因为插入表前就需要知道id值  
--  DROP TABLE [DemoTab01],[DemoTab02],[DemoTab03]  
CREATE TABLE [dbo].[DemoTab01](  
    [id] [int] NOT NULL,  
    [insdate] [datetime] NULL  
) ON [PRIMARY]  
GO  
CREATE TABLE [dbo].[DemoTab02](  
    [id] [int] NOT NULL,  
    [insdate] [datetime] NULL  
) ON [PRIMARY]  
GO  
CREATE TABLE [dbo].[DemoTab03](  
    [id] [int] NOT NULL,  
    [insdate] [datetime] NULL  
) ON [PRIMARY]  
GO  
  
--  约束每个表的范围  
ALTER TABLE [dbo].[DemoTab01] WITH CHECK ADD CONSTRAINT [CK_DemoTab01_id] CHECK ([id] BETWEEN 0 AND 99999 )  
GO  
ALTER TABLE [dbo].[DemoTab02] WITH CHECK ADD CONSTRAINT [CK_DemoTab02_id] CHECK ([id] BETWEEN 100000 AND 199999 )  
GO  
ALTER TABLE [dbo].[DemoTab03] WITH CHECK ADD CONSTRAINT [CK_DemoTab03_id] CHECK ([id] BETWEEN 200000 AND 299999 )  
GO  
  
--  既然是按id划分，把id作为聚集索引更容易定位查找  
ALTER TABLE [dbo].[DemoTab01] ADD CONSTRAINT [PK_DemoTab01_id] PRIMARY KEY CLUSTERED ([id] ASC)  
GO  
ALTER TABLE [dbo].[DemoTab02] ADD CONSTRAINT [PK_DemoTab02_id] PRIMARY KEY CLUSTERED ([id] ASC)  
GO  
ALTER TABLE [dbo].[DemoTab03] ADD CONSTRAINT [PK_DemoTab03_id] PRIMARY KEY CLUSTERED ([id] ASC)  
GO  
  
  
--  每个字段名称列出，避免用星号，否则升级增删字段不同时会出错  
--  DROP VIEW [dbo].[V_DemoTab]  
CREATE VIEW [dbo].[V_DemoTab]  
AS  
SELECT [id],[insdate] FROM [dbo].[DemoTab01]  
UNION ALL  
SELECT [id],[insdate] FROM [dbo].[DemoTab02]  
UNION ALL  
SELECT [id],[insdate] FROM [dbo].[DemoTab03]  
GO  
  
--  121317行数据  
INSERT INTO [V_DemoTab]([id],[insdate])  
SELECT SalesOrderDetailID,ModifiedDate FROM AdventureWorks2012.Sales.SalesOrderDetail  
GO  
  
  
SELECT COUNT(*) FROM [dbo].[V_DemoTab]  
SELECT COUNT(*) FROM [dbo].[DemoTab01]  
SELECT COUNT(*) FROM [dbo].[DemoTab02]  
SELECT COUNT(*) FROM [dbo].[DemoTab03]