ORACLE自动备份-压缩格式,定期删除.bat

标签：win   oracle   删除   windows   安装位置   导出文件   软件   完成后   exp   

@echo off
echo ================================================
echo Windows环境下Oracle数据库的自动备份脚本--YPWANG
echo 1. 使用当前日期命名备份文件。
echo 2. 采用WinRAR压缩DMP和LOG文件
echo 3. 自动删除30天前的备份。（可修改）
echo ================================================
::以“YYYYMMDD”格式取出当前时间。
set BACKUPDATE=%date:~0,4%%date:~5,2%%date:~8,2%
::设置用户名、密码和要备份的数据库。
set USER=ddaccrm
set PASSWORD=123
set DATABASE=orcl
::创建备份目录。
::下面修改为自己的设置
if not exist "I:\backup" mkdir I:\backup
set BACKUP=I:\backup
::软件winrar 安装位置可执行文件，注意路径不要有空格
set RAREXE=e:\WinRAR\rar.exe

::执行导出
exp %USER%/%PASSWORD%@%DATABASE% file=%BACKUP%\data_%BACKUPDATE%.dmp log=%BACKUP%\log_%BACKUPDATE%.log
::执行压缩
%RAREXE% a %BACKUP%\data_%BACKUPDATE%.rar %BACKUP%\data_%BACKUPDATE%.dmp %BACKUP%\log_%BACKUPDATE%.log
::压缩完成后执行删除导出文件
del /q %BACKUP%\data_%BACKUPDATE%.dmp
del /q %BACKUP%\log_%BACKUPDATE%.log

::删除30天前的备份。 具体删除天数把 下面30 改为自己的天数
forfiles /p %BACKUP% /s /m *.* /d -30 /c "cmd /c del @path"
exit

ORACLE自动备份-压缩格式,定期删除.bat

标签：win   oracle   删除   windows   安装位置   导出文件   软件   完成后   exp   

原文地址：https://www.cnblogs.com/yunshuijie/p/9886343.html