标签：操作 中断方式 寻址 结构 优先级 主程序 匹配 左移 tle
【数据传输指令】
一、通用数据传送指令
1、传送指令 MOV (move)
指令的汇编格式：MOV DST,SRC
指令的基本功能：(DST)<-(SRC) 将原操作数(字节或字)传送到目的地址。
指令支持的寻址方式：目的操作数和源操作数不能同时用存储器寻址方式，这个限制适用于所有指令。指令的执行对标志位的影响：不影响标志位。
指令的特殊要求：目的操作数DST和源操作数SRC不允许同时为段寄存器；
目的操作数DST不能是CS，也不能用立即数方式。
2、进栈指令 PUSH (push onto the stack)
出栈指令 POP (pop from the stack)
指令的汇编格式：PUSH SRC ；POP DST
指令的基本功能：PUSH指令在程序中常用来暂存某些数据，而POP指令又可将这些数据恢复。PUSH SRC (SP)<-(SP)-2 ；(SP)<-(SRC)
POP DST (DST)<-((SP))；(SP)<-(SP)
指令支持的寻址方式：push 和 pop指令不能不能使用立即数寻址方式。
指令对标志位的影响：PUSH 和 POP指令都不影响标志位。
指令的特殊要求：PUSH 和 POP指令只能是字操作，因此，存取字数据后，SP的修改必须是+2 或者 -2； POP指令的DST不允许是CS寄存器；
3、交换指令 XCHG (exchange)
指令的汇编格式：XCHG OPR1,OPR2
指令的基本功能：(OPR1)<->(OPR2)
指令支持的寻址方式：一个操作数必须在寄存器中，另一个操作数可以在寄存器或存储器中。
指令对标志位的影戏：不影响标志位。
指令的特殊要求：不允许使用段寄存器。
二、累加器专用传送指令
4、输入指令 IN (input)
输出指令 OUT (output)
指令的汇编格式：IN ac,port port<=0FFH
IN ac,DX port>0FFH
OUT port,ac port<=0FFH
OUT DX,ac port>0FFH
指令的基本功能：对8086及其后继机型的微处理机，所有I/O端口与CPU之间的通信都由输入输出指令IN和OUT来完成。IN指令将信息从I/O输入到CPU，OUT指令将信息从CPU输出到I/O端口，因此，IN和OUT指令都要指出I/O端口地址。
IN ac,port port<=0FFH (AL)<-(port)传送字节 或 (AX)<-(port+1,port)传送字
IN ac,DX port>0FFH (AL)<-((DX))传送字节或 (AX)<-((DX)+1,(DX))传送字
OUT port,ac port<=0FFH (port)<-(AL)传送字节 或 (port+1,port)<-(AX)传送字
OUT DX,ac port>0FFH (DX)<-(AL)传送字节 或 ((DX)+1,(DX))<-(AX)传送字
指令对标志位的影响：不影响标志位。指令的特殊要求：只限于在AL或AX与I/O端口之间传送信息。传送16位信息用AX，传送8位信息用AL，这取决于外设端口的宽度。
5、换码指令 XLAT (translate)
指令的汇编格式：XLAT opr 或 XLAT
指令的基本功能：这条指令根据AL寄存器提供的位移量，将BX指使的字节表格中的代码换存在AL中。 (AL)<-((DS)*16+(BX)+(AL))
指令对标志位的影响:不影响标志位。
指令的特殊要求：所建字节表格的长度不能超过256字节，因为存放位移量的是8位寄存器AL。opr为表格的首地址，因为opr所表示的偏移地址已存入BX寄存器，所以opr在换码指令中可有可无，有则提高程序的可读性。
三、地址传送指令
6、有效地址传送器 LEA (load effective address)
指令的汇编格式：LEA reg，src
指令的基本功能：LEA指令把源操作数的有效地址送到指定的寄存器，这个有效地址是由src选定的一种存储器寻址方式确定的。
指令支持的寻址方式：各种存储器寻址方式。
指令对标志位的影响：不影响标志位。
指令的特出要求：指令中reg不能是段寄存器；
7、指针送寄存器和DS LDS (load DS with point)
指针送寄存器和ES LES (load ES with point)
指令的汇编格式：LDS reg,src LES reg,src
指令的基本功能：LDS和LES指令把确定内存单元位置的偏移地址送寄存器，段地址DS或ES。这个偏移地址和段地址（也称地址指针）是由src指定的两个相继字单元提供的。
LDS reg,src (reg)<-(src) (DS)<-(src+2)
LES reg,src (reg)<-(src) (ES)<-(src+2)
指令支持的寻址方式：src必须为存储器寻址方式
指令对标志位的影响：不影响标志位。
指令的特殊要求：指令中REG不能是段寄存器；
四、标志寄存器传送指令
8、标志寄存器的低字节送AH LAHF (load AH with FLAGS)
指令的汇编格式：LAHF
指令的基本功能：(AH)<-(FLAGS)0-7
指令对标志位的影响：不影响标志位
9、AH送标志寄存器低字节 SAHF(store AH into FLAGS)
指令的格式：SAHF
指令的基本功能：(FLAGS)0-7<-(AH)
指令对标志位的影响：由装入值来确定标志位的值。
10、标志进栈 PUSHF (push the flags)
指令的汇编格式：PUSHF
指令的基本功能：(SP)<-(SP)-2 ((SP)+1,(SP))<-(FLAGS)0-15
指令对标志位的影响：不影响标志位。
11、标志出栈 POPF (pop the FLAGES)
指令的汇编格式：POPF
指令的基本功能：(FLAGS)0-15<-((SP)+1,(SP)) (SP)<-(SP)+2
指令对标志位的影响：由装入值来确定标志位的值。
【算术指令】
一、加法指令
12、加法指令 ADD (addition)
指令的汇编格式：add dst,src
指令的基本功能：(dst)<-(src)+(dst)
指令支持的寻址方式：他们两个操作数不能同时为存储器寻址。即为除源操作数为立即数的情况外，源操作数和目地操作数必须有一个寄存器寻址方式。
指令对标志位的影响：SF=1 加法结果为负数（符号位为1）
SF=0 加法结果为正数（符号位为0）
ZF=1 加法结果为零
ZF=0 加法结果不为零
CF=1 最高有效位向高位有进位
CF=0 最高有效位向高位无进位
OF=1 两个同符号数相加（正数+正数或负数+负数），结果符号与其相反。
OF=0 两个不同符号数相加，或同符号数相加，结果符号与其相同。
13、带进为加法指令 ADC (add with carry)
指令的汇编格式：ADD dst,src
指令的基本功能：(dst)<-(src)+(dst)+CF
指令支持的寻址方式：他们两个操作数不能同时为存储器寻址。即为除源操作数为立即数的情况外，源操作数和目地操作数必须有一个寄存器寻址方式。
指令对标志位的影响：SF=1 加法结果为负数
SF=0 加法结果为正数
ZF=1 加法结果为零
ZF=0 加法结果不为零
CF=1 最高有效位向高位有进位
CF=0 最低有效位相高位无进位
OF=1 两个同符号数相加，结果符号与其相反，
OF=0 两个同符号数相加，或同符号相加，结果符号与其相同
14、加1指令 INC (increament)
指令的汇编格式：INC opr
指令的基本功能：(opr)<-(opr)
指令支持的寻址方式 可以使用除立即数方式外的任何寻址方式
指令对标志位的影响：SF=1 加法结果为负数
SF=0 加法结果为正数
ZF=1 加法结果为零
ZF=0 加法结果不为零
OF=1 两个同符号数相加，结果符号与其相反，
OF=0 两个同符号数相加，或同符号相加，结果符号与其相同。
二、减法指令
15、减法指令 SUB (subtract)
指令的汇编格式：SUB dst,src
指令的基本功能：(dst)<-(dst)-(src)
指令支持的寻址方式：他们两个操作数不能同时为存储器寻址。即为除源操作数为立即数的情况外，源操作数和目地操作数必须有一个寄存器寻址方式。
指令对标志位的影响：SF=1 减法结果为负数（符号位为1）
SF=0 减法结果为正数（符号位为0）
ZF=1 减法结果为零
ZF=0 减法结果不为零
CF=1 二进制减法运算中最高有效位向高位有借位（被减数小于减数，不够减的情况）
CF=0 二进制减法运算中最高有效为向高位无借位（被减数〉=减数，够减的情况）
OF=1 两数符号相反（正数-负数，或负数-正数），而结果符号与减数相同。
OF=0 同符号数相减时，或不同符号数相减，其结果符号与减数不同。
16、带借位减法指令 SBB (subtract with borrow)
指令的汇编格式：SBB dst,src
指令的基本功能：(dst)<-(dst)-(src)-CF
指令支持的寻址方式：他们两个操作数不能同时为存储器寻址。即为除源操作数为立即数的情况外，源操作数和目地操作数必须有一个寄存器寻址方式。
指令对标志位的影响：SF=1 减法结果为负数（符号位为1）
SF=0 减法结果为正数（符号位为0）
ZF=1 减法结果为零
ZF=0 减法结果不为零
CF=1 二进制减法运算中最高有效位向高位有借位（被减数小于减数，不够减的情况）
CF=0 二进制减法运算中最高有效为向高位无借位（被减数〉=减数，够减的情况）
OF=1 两数符号相反（正数-负数，或负数-正数），而结果符号与减数相同。
OF=0 同符号数相减时，或不同符号数相减，其结果符号与减数不同。
17、减1指令 DEC (decrement)
指令的汇编格式：DEC opr
指令的基本功能：(opr)<-(opr)-1
指令支持的寻址方式：可以使用除立即数方式外的任何寻址方式。
指令对标志位的影响：SF=1 减法结果为负数（符号位为1）
SF=0 减法结果为正数（符号位为0）
ZF=1 减法结果为零
ZF=0 减法结果不为零
OF=1 两数符号相反（正数-负数，或负数-正数），而结果符号与减数相同。
OF=0 同符号数相减时，或不同符号数相减，其结果符号与减数不同。
18、比较指令 CMP (compare)
指令的汇编格式：CMP opr1,opr2
指令的基本功能：(opr1)-(opr2),根据相减结果设置条件码，但不回送结果。
指令支持的寻址方式：他们两个操作数不能同时为存储器寻址。即为除源操作数为立即数的情况外，源操作数和目地操作数必须有一个寄存器寻址方式。
指令对标志位的影响：
SF=1 减法结果为负数（符号位为1）
SF=0 减法结果为正数（符号位为0）
ZF=1 减法结果为零
ZF=0 减法结果不为零
CF=1 二进制减法运算中
最高有效位向高位有借位（被减数小于减数，不够减的情况）
CF=0 二进制减法运算中最高有效为向高位无借位（被减数〉=减数，够减的情况）
OF=1 两数符号相反（正数-负数，或负数-正数），而结果符号与减数相同。
OF=0 同符号数相减时，或不同符号数相减，其结果符号与减数不同。
19、求补指令 NEG (negate)
指令的汇编格式：NEG opr
指令的基本功能：(opr)<- -(opr)
指令支持的寻址方式：可以使用除立即数方式外的任何寻址方式。
指令对标志位的影响：CF=1 不为0的操作数求补时
CF=0 为0的操作数求补时
OF=1 操作数为-128（字节运算）或操作数为-32768（字运算）
OF=0 当求补运算的操作数不为－128（字节）或－32768（字）时三、乘法指令
20、无符号乘法指令 NUL (unsigned multiple)
有符号乘法指令 IMUL(signed muliple)
指令的汇编格式：NUL src IMUL src
指令的基本功能：(AX)<-(AL)*(src) (DX,AX)<-(AX)*(src)
指令支持的寻址方式：src可以使用除立即数方式以外的任一种寻址方式。
指令对标志位的影响：乘法指令只影响标志位CF和OF，其他条件码位无定义。
MUL指令的条件码设置为：
CF OF=0 0 乘积的高一半为0（字节操作的（AH）或字操作的（DX））
CF OF=1 1 乘积的高一半不为0
IMUL指令的条件码设置为：
CF OF=0 0 乘积的高一半为低一半的符号扩展.
CF OF=1 1 其他情况
指令的特殊要求：MUL和IMUL指令的区别仅在于操作数是无符号还是带符号数，它们的共同点是，指令中只给出源操作数src，目的操作数是隐含的，它只能是累加器（字运算为AX，字节运算为AL）。隐含的乘积寄存器是AX或DX（高位）和AX（低位）。
四、符号扩展指令
21、节扩展为字 CBW (convert byte to word)
指令的汇编格式：CBW
指令的基本功能：(AH)=00H 当(AL)的最高有效位为0时
(AH)=FFH 当(AL)的最高有效位为1时
指令对标志位的影响：不影响标志位
指令的特殊要求：这是条无操作数的指令，进行符号扩展的操作数必须存放在AL寄存器 AX寄存器中。
22、字扩展为双字 CWD (convert word to double word)
指令的汇编格式：CWD
指令的基本功能：(DX)=0000H 当(AX)的最高有效位为0时
(DX)=FFFFH 当(AX)的最高有效位为1时
指令对标志位的影响：不影响标志位
指令的特殊要求：这是条无操作数的指令，进行符号扩展的操作数必须存放在AL寄存器或AX寄存器中。
五、除法指令
23、无符号数除法 DIV (unsigned divide)
带符号数除法 IDIV (singed divide)
指令的汇编格式：DIV src IDIV src
指令的基本功能：字操作
(AL)<-(AX)/src的商 (AH)<-(AX)/src的余数
字节操作
(AX)<-(DX,AX)/src的商 (DX)<-(DX,AX)/src的余数
指令支持的寻址方式：src作为除数，可用除立即数以外的任一种寻址方式来取得。
指令对标志位的影响：不影响条件码。
指令的特殊要求：除法指令要求字操作时，被除数必须为32位，除数是16位，商和余数是16位的；字节操作时，被除数必须为16位，除数是8位，得到的商和余数是8位的。
六、十进制调整指令
【逻辑指令】
一、逻辑运算
指令的格式：AND dst,src
指令的基本功能：(dst)<-(dst)与(src)
指令支持的寻址方式：两个操作数不能同时为存储器寻址。即为除源操作数为立即数的情况外，源操作数和目地操作数必须有一个寄存器寻址方式。
指令对标志位的影响：指令执行后 CF 和 OF 置零，AF无定义。
SF=1 指令执行后的结果为负数（符号位为1）
SF=0 指令执行后的结果为正数（符号位为0）
ZF=1 指令执行后的结果为零
ZF=0 指令执行后的结果不为零
PF=1 结果操作数中1的个数为偶数时置1
PF=0 结果操作数中1的个数为奇数时置0
25、逻辑或 OR (logic or)
指令的汇编格式：OR dst，src
指令的基本功能：(dst)<-(dst)或(src)
指令支持的寻址方式：两个操作数不能同时为存储器寻址。即为除源操作数为立即数的情况外，原操作数和目的操作数必须有一个寄存器寻址方式。
指令对标志位的影响：令执行后 CF 和 OF 置零，AF无定义。
SF=1 指令执行后的结果为负数（符号位为1）
SF=0 指令执行后的结果为正数（符号位为0）
ZF=1 指令执行后的结果为零
ZF=0 指令执行后的结果不为零
PF=1 结果操作数中1的个数为偶数时置1
PF=0 结果操作数中1的个数为奇数时置0
26、逻辑非 NOT (logic not)
指令的汇编格式：NOT orc
指令的基本功能：(dst)<-(opr)
指令支持的寻址方式：除立即数寻址方式以外的其余寻址方式
指令对标志位的影响：对标志位无影响
27、异或 XOR (exclusice or)
指令的汇编格式：XOR dst,src
指令的基本功能：(dst)<-(dst)异或(src)
指令支持的寻址方式：两个操作数不能同时为存储器寻址。即为除源操作数为立即数的情况外，原操作数和目的操作数必须有一个寄存器寻址方式。
指令对标志位的影响：令执行后 CF 和 OF 置零，AF无定义。
SF=1 指令执行后的结果为负数（符号位为1）
SF=0 指令执行后的结果为正数（符号位为0）
ZF=1 指令执行后的结果为零
ZF=0 指令执行后的结果不为零
PF=1 结果操作数中1的个数为偶数时置1
PF=0 结果操作数中1的个数为奇数时置0
28、测试指令 TEST
指令的汇编格式：TEST opr1,opr2
指令的基本功能：(opr1)与(opr2)
指令支持的寻址方式：两个操作数不能同时为存储器寻址，即为除源操作数为立即数的情况外，源操作数和目的操作数必须有一个寄存器寻址方式。
指令对标志位的影响：令执行后 CF 和 OF 置零，AF无定义。
SF=1 指令执行后的结果为负数（符号位为1）
SF=0 指令执行后的结果为正数（符号位为0）
ZF=1 指令执行后的结果为零
ZF=0 指令执行后的结果不为零
PF=1 结果操作数中1的个数为偶数时置1
PF=0 结果操作数中1的个数为奇数时置0
二、移位指令
29、逻辑左移 SHL (shift logical left)
指令的汇编格式：SHL dst,cnt
指令的基本功能：SHL指令向左逐位移动cnt次，每次逐位移动后，最低位用0来补充，最高位移入CF。
指令支持的寻址方式：目的操作数dst可以是除立即数外的任何寻址方式。移位次数（或位数）cnt=1时，1可以直接写在指令中，cnt〉1时，cnt必须放入CL寄存器中。
指令对标志位的影响：CF=移入的数值
OF=1 当cnt=1时，移动后最高位的值发生变化。
OF=0 当cnt=1时，移动时最高位的值未发生变化。
SF、ZF、PF根据移动后的结果设置
30、逻辑右移 SHR (shift logical right)
指令的汇编格式：SHR dst,cnt
指令的基本功能：SHR指令向右逐位移动cnt次，每次逐位移动后，最高位用0来补充，最低位移入CF。
指令支持的寻址方式：目的操作数dst可以是除立即数外的任何寻址方式。移位次数（或位数）cnt=1时，1可以直接写在指令中，cnt〉1时，cnt必须放入CL寄存器中。
指令对标志位的影响：CF=移入的数值
OF=1 当cnt=1时，移动后最高位的值发生变化。
OF=0 当cnt=1时，移动时最高位的值未发生变化。
SF、ZF、PF根据移动后的结果设置。
31、算术左移 SAL (shift arithmetic left)
指令的汇编格式：SAL dst cnt
指令的基本功能：SAL指令向左逐位移动cnt次，每次逐位移动后，最低位用0来补充，最高位移入CF。
指令支持的寻址方式：目的操作数dst可以是除立即数外的任何寻址方式。移位次数（或位数）cnt=1时，1可以直接写在指令中，cnt〉1时，cnt必须放入CL寄存器中。
指令对标志位的影响：CF=移入的数值
OF=1 当cnt=1时，移动后最高位的值发生变化。
OF=0 当cnt=1时，移动时最高位的值未发生变化。
SF、ZF、PF根据移动后的结果设置。
32、算术右移 SAR (shift arithmetic right)
指令的汇编格式：SAR dst,cnt
指令的基本功能：SAR指令向右逐位移动cnt次，每次逐位移动后，最高位用符号位来补充，最低位移入CF。
指令支持的寻址方式：目的操作数dst可以是除立即数外的任何寻址方式。移位次数（或位数）cnt=1时，1可以直接写在指令中，cnt〉1时，cnt必须放入CL寄存器中。
指令对标志位的影响：CF=移入的数值
OF=1 当cnt=1时，移动后最高位的值发生变化。
OF=0 当cnt=1时，移动时最高位的值未发生变化。
SF、ZF、PF根据移动后的结果设置。
33、循环左移 ROL (rotate left)
指令的汇编格式：ROL dst,cnt
指令的基本功能：ROL 对由dst指定的寄存器或存储器操作数左移循环移动cnt所指定的次数，每左移一次，把最高位同时移入CF和操作数最低位。
指令支持的寻址方式：目的操作数dst可以是除立即数外的任何寻址方式。移动次数（或位数）cnt=1时，1可以直接写在指令中，cnt〉1时，cnt必须放入CL寄存器中。
指令对标志位的影响：CF=移入的数值
OF=1 当cnt=1时，移动后最高位的值发生变化。
OF=0 当cnt=1时，移动时最高位的值未发生变化。
SF、ZF、PF根据移动后的结果设置。
34、循环右移 ROR (rotate right)
指令的汇编格式：ROR dst,cnt
指令的基本功能：ROR 对由dst指定的寄存器或存储器操作数右移循环移动cnt所指定的次数，每右移一次，把最低位同时移入CF和操作数最高位。
指令支持的寻址方式：目的操作数dst可以是除立即数外的任何寻址方式。移动次数（或位数）cnt=1时，1可以直接写在指令中，cnt>1时，cnt必须放入CL寄存器中。
指令对标志位的影响：CF=移入的数值
OF=1 当cnt=1时，移动后最高位的值发生变化。
OF=0 当cnt=1时，移动时最高位的值未发生变化。
SF、ZF、PF根据移动后的结果设置。
35、带进位的循环左移 RCL (rotate left through carry)
指令的汇编格式：RCL dst,cnt
指令的基本功能：RCL 对由dst指定的寄存器或存储器操作数，连同进位标志CF左循环移动，m所指定的次数，每左移一次，把操作数的最高位移入CF，而CF中原有内容移入操作数的最低位。
指定支持的寻址方式：目的操作数dst可以是除立即数外的任何寻址方式。移动次数（或位数）cnt=1时，1可以直接写在指令中，cnt〉1时，cnt必须放入CL寄存器中。
指令对标志位的影响：CF=移入的数值。
OF=1 当cnt=1时，移动后最高位的值未发生变化。
OF=0 当cnt=1时，移动后最高位的值发生变化。
SF、ZF、PF标志位不受影响。
36、带进位的循环右移 RCR (rotate right through carry)
指令的汇编格式：RCR dst，cnt
指令的基本功能：RCR 对由dst指定的寄存器或存储器操作数，连同进位标志CF右循环移动，m所指定的次数，每右移一次，把操作数的最高低位移入CF，而CF中原有内容移入操作数的最高位。
指令支持的寻址方式：目的操作数dst可以是除立即数外的任何寻址方式。移动次数（或位数）cnt=1时，1可以直接写入指令中，cnt〉1时，cnt必须放入CL寄存器中。
指令对标志位的影响：CF=移入的数值。
OF=1 当cnt=1时，操作数最高位的值未发生变化。
OF=0 当cnt=1时，操作数最高位的值发生变化。
SF、ZF、PF标志位不受影响。
【串处理指令】
一、设置方向标志指令
37、DF置零 CLD (clear direction flag)
DF置一 STD (set direction flag)
指令的汇编格式：CLD
STD
指令的基本功能：CLD DF=0
STD DF=1
二、串处理指令
38、串传送 MOVSB / MOVSW (move string byte/word)
指令的汇编格式：MOVSB
MOVSW
指令的基本功能：(ES:DI)<-(DS:SI)
(SI)<-(SI)+/-1(字节)或+/-2(字)
(DI)<-(DI)+/-1(字节)或+/-2(字)
指令对条件码的影响：不影响条件码。
指令的特殊要求：源串必须在数据段中，目的串必须在附加段中，串处理指令隐含的寻址方式是SI和DI寄存器的间接寻址方式。源串允许使用段跨越前缀来指定段。
39、存串 STOSB / STOSW (stroe from string byte/word)
指令的汇编格式：STOSB
STOSW
指令的基本功能：(ES:DI)<-(AL)或(AX)
(DI)<-(DI)+/-1(字节)或+/-2(字)
指令对条件码的影响：不影响条件码。
指令的特殊要求：源串必须在数据段中，目的串必须在附加段中，串处理指令隐含的寻址方式是SI和DI寄存器的间接寻址方式。源串允许使用段跨越前缀来指定段。
40、取串LODSB / LODSW (load from string byte/word)
指令的汇编格式：LODSB
LODSW
指令的基本功能：(AL)或(AX)<-(DS:SI)
(SI)<-(SI)+/-1(字节)或+/-2(字)
指令对条件码的影响：不影响条件码。
指令的特殊要求：源串必须在数据段中，目的串必须在附加段中，串处理指令隐含的寻址方式是SI和DI寄存器的间接寻址方式。源串允许使用段跨越前缀来指定段。
41、串比较 CMPSB / CMPSW (compare string byte/word)
指令的汇编格式：CMPSB
CMPSW
指令的基本功能：(DS:SI)-(ES:DI) 根据比较结果设置条件码
(SI)<-(SI)+/-1(字节)或+/-2(字)
(DI)<-(DI)+/-1(字节)或+/-2(字)
指令对条件码的影响：SF=1 减法结果为负数（符号位为1）
SF=0 减法结果为正数（符号位为0）
ZF=1 减法结果为零
ZF=0 减法结果不为零
CF=1 二进制减法运算中最高有效位向高位有借位（被减数小于减数，不够减的情况）
CF=0 二进制减法运算中最高有效为向高位无借位（被减数〉=减数，够减的情况）
OF=1 两数符号相反（正数-负数，或负数-正数），而结果符号与减数相同。
OF=0 同符号数相减时，或不同符号数相减，其结果符号与减数不同。
42、串扫描 SCASB / SCASW (scan string byte / word)
指令的格式：SCASB
SCASW
指令的基本功能：(AL)<-(ES:DI)或(AX)<-(ES:DI) 根据扫描比较的结果设置条件码。
(DI)<-(DI)+/-1(字节)或+/-2(字)
指令对条件码的影响：SF=1 结果为负数（符号位为1）
SF=0 结果为正数（符号位为0）
ZF=1 结果为零
ZF=0 结果不为零
CF=1 二进制减法运算中最高有效位向高位有借位（被减数小于减数，不够减的情况）
CF=0 二进制减法运算中最高有效为向高位无借位（被减数〉=减数，够减的情况）
OF=1 两数符号相反（正数-负数，或负数-正数），而结果符号与减数相同。
OF=0 同符号数相减时，或不同符号数相减，其结果符号与减数不同。
三、串重复前缀
43、重复执行串 REP
指令的汇编格式：REP (CX)=重复次数
指令的基本功能：① (CX)=0时，串指令执行完毕，否则执行② ~ ④
② (CX)←(CX)－1③ 执行串指令（MOVS或STOS）④ 重复执行①
44、相等/为零时重复执行串指令 REPE/REPZ
指令的汇编格式：REPE / REPZ (CX)=比较/扫描的次数
指令的基本功能：① (CX)=0或ZF=0时，结束执行串指令，否则继续② ~ ④
② (CX)←(CX)－1③ 执行串指令（CMPS或SCAS）④ 重复执行①
45、不等/不为零时重复执行串指令 REPNE / PEPNZ
指令的汇编格式：REPNE / PEPNZ (CX)=比较/扫描的次数
指令的基本功能：① (CX)=0或ZF=1，结束执行串指令，否则继续② ~ ④
② (CX)←(CX)－1③ 执行串指令（CMPS或SCAS）④ 重复执行①
【控制转移指令】
一、无条件转移指令
46、短转移 JMP SHORT label (short jump)
指令的汇编格式：JMP SHORT label
指令的基本功能：(IP)<-当前(IP)+8位位移量 8位位移量是汇编程序在汇编源程序时，根据目标地址和当前IP之间的距离自动生成的。
指令对条件码的影响：对标志位无影响。
47、近转移 JMP NEAR PTR label (near jump)
指令的汇编格式：直接转移 JMP label (direct jump)
寄存器间接转移 JMP reg (register indirect jump)
存储器间接转移 JMP WORD PTR OPR (memory indirect jump)
指令的基本功能：JMP label (IP) <- OFFSET label = (IP)当前＋16位位移量
JMP reg (IP) <- (reg)
JMP WORD PTR OPR (IP) <- (PA+1,PA)
指令支持的寻址方式：指令中的转向地址可以是直接寻址方式、寄存器寻址方式、寄存器间接寻址方式和存储器寻址方式。
指令对条件码的影响：对标志位无影响。
48、远转移 JMP FAR PTR label (for jump)
指令的汇编格式：JMP FAR PTR label
指令的基本功能：(IP)<-label的段内偏移地址 (CS)<-label所在段的段地址
指令支持的寻址方式：远转移的目的地址可以使用除立即寻址方式外的任何寻址方式来表示。指令对条件码的影响：对标志位无影响。
二、条件转移指令
指令的汇编格式及功能
根据条件码的值转移：
49、JZ(JE) OPR ZF=1 ZF=0（运算结果为0，ZF就置1）
50、JNZ(JNE) OPR ZF=0
51、JS OPR SF=1 SF=0（二进制最高位是什么,SF就是什么，如最高位为1则SF=1）
52、JNS OPR SF=0
53、JO OPR OF=1 OF=1 (两个负数相加变成正数，溢出）
54、JNO OPR OF=0
55、JP OPR PF=1 PF=0 (反映结果“1”的个数，奇数?0 偶数个?1）
56、JNP OPR PF=0
57、JC OPR CF=1 CF=1（最高位有进位或借位就置1）
58、JNC OPR CF=0
比较两个无符号数，根据比较的结果转移
59、JB(JNAE,JC) OPR CF=1 被减数小于减数则转移
60、JNB(JAE,JNC) OPR CF=0 被减数大于或等于减数则转移
61、JBE(JNA) OPR CF或ZF=1 被减数小于或等于减数则转移
62、JNBE(JA) OPR CF或ZF=0 被减数大于减数则转移
比较两个带符号数，根据比较结果转移
63、JL/JNGE OPR SF异或OF=1 被减数小于减数则转移
64、JNL/JGE SF异或OF=0 被减数不小于减数则转移
65、JLE/JNE (SF异或OF)与ZF=1 被减数不大于减数则转移
66、JNLE/JG (SF异或OF)与ZF=0 被减数大于减数则转移
根据CX寄存器的值转移
67、JCXZ (CX)=0 CX内容为零则转移
指令的特殊要求：所有条件转移指令都是短转移指令，转移的目标地址必须在当前IP地址的-128至+127字节范围之内，因此条件转移指令是2字节指令。
三、循环指令
68、循环 LOOP (loop)
指令的汇编格式：LOOP label
指令的基本功能：① (CX)←(CX)－1 ② 若(CX)≠0，则(IP)←(IP)当前＋位移量，否则循环结束。
指令的特殊要求：循环指令都是短转移格式的指令，也就是说，位移量是用8位带符号数来表示的，转向地址在相对于当前IP值的－128 ~ ＋127字节范围之内。
69、为零/相等时循环 LOOPZ/LOOPE (loop while nonzero or equal)
指令的汇编格式：LOOPNZ/LOOPNE label
指令的基本功能：① (CX)←(CX)－1
② 若ZF=1且(CX)≠0，则(IP)←(IP)当前＋位移量，否则循环结束。
指令的特殊要求：循环指令都是短转移格式的指令，也就是说，位移量是用8位带符号数来表示的，转向地址在相对于当前IP值的－128 ~ ＋127字节范围之内。
70、不为零/不相等时循环 LOOPNZ/LOOPNE (loop while nonzero or not equal)
指令的汇编格式：LOOPNZ/LOOPNE label
指令的基本功能：① (CX)←(CX)－1
② 若ZF=0且(CX)≠0，则(IP)←(IP)当前＋位移量，否则循环结束。
指令的特殊要求：循环指令都是短转移格式的指令，也就是说，位移量是用8位带符号数来表示的，转向地址在相对于当前IP值的－128 ~ ＋127字节范围之内。
四、子程序调用
71、段内直接近调用 CALL SUBROUT
指令的基本功能：(SP)<-(SP)-2
((SP)+1,(sp))<-(IP)
(IP)<-(IP)+16位位移量
段内间接近调用 CALL DESTIN
指令的基本功能：(SP)<-(SP)-2
((SP)+1,(SP))<-(IP)
(IP)<-(EA)
72、段间直接调用 CALL FAR PTR SUBROUT
指令的基本功能：(SP)<-(SP)-2,((SP))<-(CS)当前
(SP)<-(SP)-2,((SP))<-(IP)当前
(IP)<-偏移地址(在指令的第2、3个字节)
(CS)<-段地址(在指令的第4、5个字节)
五、返回指令
73、段内返回(近返回) RET
指令的基本功能：(IP)<-((SP)+1,(SP))
(SP)<-(SP)+2
段间返回(远返回) RET
指令的基本功能：(IP)<-((SP)),(SP)<-(SP)+2
(CS)<-((SP)),(SP)<-(SP)+2
带立即数返回 RET N
执行操作：① 返回地址出栈（操作同段内或段间返回）
② 修改堆栈指针：(SP) ← (SP)＋N
六、中断及中断返回指令
74、INT n 中断指令（interrupt），n为中断类型号
执行操作：① 入栈保存FLAGS：(SP) ← (SP)－2，((SP)) ← (FLAGS)
② 入栈保存返回地址：(SP) ← (SP)－2，((SP)) ← (CS)
(SP) ← (SP)－2，((SP)) ← (IP)
③ 转中断处理程序：(IP) ← (n×4)
(CS) ← (n×4＋2)
75、IRET 中断返回指令（return from interrupt）
执行操作：① 返回地址出栈：(IP) ← ((SP))，(SP) ← (SP)＋2
(CS) ← ((SP))，(SP) ← (SP)＋2
② FLAGS出栈：(FLAGS) ← ((SP))，(SP) ← (SP)＋2
76、INTO 溢出则中断（中断类型为4）
执行操作：若OF=1（有溢出），则：
① 入栈保存FLAGS：(SP) ← (SP)－2，((SP)) ← (FLAGS)
② 入栈保存返回地址：(SP) ← (SP)－2，((SP)) ← (CS)
(SP) ← (SP)－2，((SP)) ← (IP)
③ 转中断处理程序：(IP) ← (4×4)= (10H)
(CS) ← (4×4＋2)= (12H
HELLO,WORLD进阶汇编程序系列
Editor:admin Time:2004-3-21 12:49 Read:9785 Score:8 Print
Writer:LLUCT
Excerpt:80x86汇编小站
Preface：
感谢网友lluct为本站提供原创......适合初学者学习哦
Content：
TITLE ***HELLO,WORLD进阶程序之选择分支 BY LLUCT***
DATA SEGMENT ;定义数据段
MSG1 DB ‘***WELCOME TO MY PROGRAM BY LLUCT***‘,‘$‘
;定义输出的第一个字符串信息,字符串必须用DB定义,$为结束标志
MSG2 DB ‘1:BASIC MESSAGE 2:ADVANCED MESSAGE‘,‘$‘
;定义输出的字符串信息:选择菜单
MSG3 DB ‘PLEASE CHOOSE:‘,‘$‘
;定义输出的字符串信息:选择前缀
MSG4 DB ‘HELLO,WORLD!^-^‘,‘$‘
;定义输出的字符串信息:分支1的信息
MSG5 DB ‘THIS IS MY FIRST ASM_86 PROGRAM! @^-^@‘,‘$‘
;定义输出的字符串信息:分支2的信息
ERRMSG DB ‘CHOOSE ERROR! -_-b‘,‘$‘
;定义输出的字符串信息:选择错误信息
DATA ENDS ;数据段结尾
CODE SEGMENT ;定义代码段
ASSUME CS:CODE ;规定CS的内容
ASSUME DS:DATA ;规定DS的内容
START: MOV AX,DATA ;程序从START开始
MOV DS,AX ;DS置初值,DATA的段地址
CALL ENTER ;调用显示回车换行子程序
LEA DX,MSG1 ;输出第一个字符串的偏移地址
CALL DISPCHS ;调用显示字符串子程序
CALL ENTER ;调用显示回车换行子程序
CALL ENTER ;这个...同上啊^-^
LEA DX,MSG2 ;输出第二个字符串的偏移地址
CALL DISPCHS ;调用显示字符串子程序
AGAIN: CALL ENTER ;定义AGAIN标号.用于选择错误循环
LEA DX,MSG3 ;输出第三个字符串的偏移地址
CALL DISPCHS ;调用显示字符串子程序
MOV AH,01H ;调用1号功能:从键盘输入一个字符并回显
INT 21H ;完成输入回显
CMP AL,‘1‘ ;输入的字符和1相比较
JE BASICP ;如果相等,转移到BASICP标号(JE=Jump if Equal)
CMP AL,‘2‘ ;输入的字符和2相比较 ||
JE ADVANP ;如果相等,转移到ADVANP标号(JE=如果相等就转移)
JMP ERROR ;否则就无条件转移到ERROR标号
EXIT: MOV AH,4CH ;4C号功能调用:终止当前程序并返回调用程序
INT 21H ;返回DOS
BASICP: CALL ENTER ;什么,还要解释啊.晕-_-!!!
LEA DX,MSG4 ;输出第三个字符串的偏移地址
CALL DISPCHS ;调用显示字符串子程序
CALL ENTER ;..........
JMP EXIT ;无条件转移到EXIT标号
ADVANP: CALL ENTER ;55555555
LEA DX,MSG5 ;解释了四次,应该懂了吧
CALL DISPCHS ;调用显示字符串子程序
CALL ENTER ;再问就死给你看
JMP EXIT ;无条件转移到EXIT标号
ERROR: CALL ENTER
LEA DX,ERRMSG ;输出选择错误信息
CALL DISPCHS ;调用显示字符串子程序
MOV DL,07H ;输出ASCII码的报警(响铃)控制符BEL(07H)
CALL DISPCH ;调用显示单个字符子程序
CALL ENTER
JMP AGAIN
DISPCH PROC NEAR
;显示单个字符子程序,NEAR说明子程序和主程序在同一个代码段中(现无主程序调用)
MOV AH,02H ;2号功能调用:显示器输出字符
INT 21H ;完成输出显示
RET ;返回
DISPCH ENDP ;子程序结尾
ENTER PROC NEAR ;显示回车换行子程序
MOV DL,0DH ;输出ASCII码的回车控制符CR(0DH)
CALL DISPCH ;调用显示单个字符子程序
MOV DL,0AH ;输出ASCII码的换行控制符LF(0AH)
CALL DISPCH ;调用显示单个字符子程序
RET ;返回
ENTER ENDP ;子程序结尾
DISPCHS PROC NEAR
;显示字符串子程序,NEAR说明子程序和主程序在同一个代码段中(现无主程序调用)
MOV AH,09H ;9号功能调用:显示字符串
INT 21H ;完成输出显示
RET
DISPCHS ENDP
CODE ENDS ;代码段结尾
END START ;结束汇编
;把以上代码复制到记事本等文本程序中,并保存.(如helloch.asm)
;编译:masm helloch.asm
;连接:link helloch.obj
;执行:helloch.exe
======================================================
title ***hello,world进阶之字符串输入输出 by lluct***
data segment ;定义数据段
input db 100 dup(?)
;定义输入的字符串,字符串必须用db定义,长度为100个字节
msg1 db ‘Hello,‘,‘$‘
;定义输出的前缀字符串信息,字符串必须用db定义,$为结束标志(24h)
msg2 db ‘,Welcome to here!‘,‘$‘
;定义输出的后缀字符串信息
headmsg db ‘PLEASE INPUT YOUR NAME:‘,‘$‘
;开始显示的字符串信息
data ends ;数据段结尾
code segment ;定义代码段
assume cs:code ;规定cs的内容
assume ds:data ;规定ds的内容
start: mov ax,data ;程序从start开始
mov ds,ax ;ds置初值,data的段地址
mov si,0 ;变址寄存器置初值0
call enter ;调用显示回车换行子程序
lea dx,headmsg ;输出开始显示的字符串的偏移地址
call dispchs ;调用显示字符串子程序
repeat: mov ah,01h
;定义repeat标号,用于循环输入单个字符.调用1号功能:从键盘输入一个字符并回显
int 21h ;完成输入回显
cmp al,0dh ;输入的字符和CR(回车)比较
je exit ;如果等于回车就转移到exit
mov input[si],al ;把al的值传送到input的si地址中(好像是这样吧)
inc si ;si加1
jmp repeat ;无条件转移到repeat
exit: call enter
mov input[si],24h ;给输入完成的字符串加上结束标志($)
call enter
lea dx,msg1 ;输出前缀字符串的偏移地址
call dispchs ;调用显示字符串子程序
lea dx,input ;输出刚才输入的字符串
call dispchs
lea dx,msg2
call dispchs
call enter
mov ah,4ch ;4c号功能调用:终止当前程序并返回调用程序
int 21h ;返回dos
enter proc near ;显示回车换行子程序
mov dl,0dh ;输出ascii码的回车控制符cr(0dh)
call dispch
mov dl,0ah ;输出ascii码的换行控制符lf(0ah)
call dispch
ret ;返回
enter endp ;子程序结束
dispch proc near
mov ah,02h ;2号功能调用:显示器输出字符
int 21h ;完成输出显示
ret ;返回
dispch endp
dispchs proc near
mov ah,09h ;9号功能调用:显示字符串
int 21h ;完成输出显示
ret ;返回
dispchs endp
code ends ;代码段结尾
end start ;结束汇编
;把以上代码复制到记事本等文本程序中,并保存.(如heinout.c)
;编译:masm heinout.asm
;连接:link heinout.obj
;执行:heinout.exe
中断是指CPU对系统发生的某个事件作出的一种反应：CPU暂停正在执行的程序，保留现场后自动转去执行相应的处理程序，处理完该事件后再返回断点继续执行被"打断"的程序
在我们所用的电脑中，所有的硬件都需要执行中断请求的动作，简单说它的作用就是用来停止其相关硬件的工作状态。我们可以举一个日常生活中的例子来说明，假如你正在给朋友写信，电话铃响了，这时你放下手中的笔去接电话，通话完毕再继续写信。这个例子就表现了中断及其处理的过程：电话铃声使你暂时中止当前的工作，而去处理更为急需处理的事情——接电话，当把急需处理的事情处理完毕之后，再回过头来继续原来的事情。在这个例子中，电话铃声就可以称为“中断请求”，而你暂停写信去接电话就叫作“中断响应”，那么接电话的过程就是“中断处理”。由此我们可以看出，在计算机执行程序的过程中，由于出现某个特殊情况(或称为“事件”)，使得系统暂时中止现行程序，而转去执行处理这一特殊事件的程序，处理完毕之后再回到原来程序的中断点继续向下执行，而这个过程就被称为中断。
中断的作用
我们可以再举一个例子来说明中断的作用。假设有一个朋友来拜访你，但是由于不知何时到达，你只能在门口等待，于是什么事情也干不了；但如果在门口装一个门铃，你就不必在门口等待而可以在家里去做其他的工作，朋友来了按门铃通知你，这时你才中断手中的工作去开门，这就避免了不必要的等待。而计算机也一样，例如打印文稿的操作。因为cpu传送数据的速度高，而打印机速度较慢，如果不采用中断技术，cpu将经常处于等待状态，这会使得电脑的工作效率极低。而采用了中断方式后，cpu就可以在打印的同时进行其他的工作，而只在打印机缓冲区内的当前内容打印完毕，而发出中断请求之后才予以响应，这时才暂时中断当前的工作转去执行停止打印的操作，之后再返回执行原来的程序。这样就大大地提高了计算机系统的效率。
irq中断
计算机中的中断有好几种，根据中断信号产生的来源可以分为：硬件中断和软件中断。硬件中断多由外围设备和计算机系统控制器发出，软件中断一般由软件命令产生。在硬件中断中又有“可屏蔽中断”和“不可屏蔽中断”之分。顾名思义，可屏蔽中断可以由计算机根据系统的需要来决定是否进行接收处理或是延后处理(即屏蔽)，而不可屏蔽中断便是直接激活相应的中断处理程序，它不能也不会被延误。而irq中断就是可屏蔽的硬件中断，它的全称为interrupt request 即“中断请求”。
在电脑的系统中，是由一个中断控制器8259或是8259a的芯片(现在此芯片大都集成到其他的芯片内)来对系统中每个硬件的中断进行控制。目前共有16组irq，去掉其中用来作桥接的一组irq，实际上只有15组irq可供硬件调用。而这些irq都有自己建议的配置。
分配irq中断
我们日常所用的操作系统对于irq的设置也不尽相同，所以在安装新硬件的时候，系统往往并不能自动检测正确的irq来分配给所需调用的硬件，这就会造成此硬件设备或是原来的旧硬件出现不能正常工作的现象。其实这是系统自动将该硬件的irq分配给了其他与此irq相同的硬件上，从而发生冲突使硬件不能正常工作。一般如果遇到这种情况，只要将新旧两个硬件的irq配置手动调开就可以解决了。
对于一些常用的硬件一般都有其默认的irq数值。比如声卡常常使用irq5或7。虽然这些配件使用其他的irq值大多数也能工作，但假如碰到特别“挑剔”的软件或游戏等程序，例如只能识别irq值为5或7的声卡，那么如果将它设成irq9就白费心机了。
8.3.1 中断的基本概念
中断(Interrupt)是指计算机在实行期间，系统内发生非寻常的或非预期的急需处理事件，使得CPU暂时中断当前正在执行的程序而转去执行响应的事件处理程序。待处理完毕后又返回原来中断处继续执行或调度新的程序执行的过程。
现代计算机系统一般都具有处理突发事件的能力。例如：从磁带上读入一组信息，当发现读入信息有错误时，只要让磁带退回重读该组信息就可能克服错误，而得到正确的信息。
这种处理突发事件的能力是由硬件和软件协作完成的。首先由硬件的中断装置发现产生的事件，然后，中断装置中止现行程序的执行，引出处理该事件的程序来处理。计算机系统不仅可以处理由于硬件或软件错误而产生的事件，而且可以处理某种预定处理伪事件。例如：外围设备工作结束时，也发出中断请求，向系统报告它已完成任务，系统根据具体情况作出相应处理。引起中断的事件称为中断源。发现中断源并产生中断的硬件称中断装置。在不同的硬件结构中，通常有不同的中断源和平不同的中断装置，但它们有一个共性，即：当中断事件发生后，中断装置能改变处理器内操作执行的顺序。
中断源：引起中断发生的事件被称为中断源。
中断请求：中断源向CPU发出的请求中断处理信号。
中断响应：CPU收到中断请求后转相应的事件处理程序。
禁止中断（关中断）：CPU内部的处理机状态字PSW的中断允许位已被清除，不允许CPU响应中断。
开中断：PSW的中断允许位的设置。
中断屏蔽：在中断请求产生之后，系统用软件方式有选择地封锁部分中断而允许蓁部分的中断仍能得到响应。
8.3.4 中断处理过程
中断处理过程：
(1) CPU检查响应中断的条件是否满足。CPU响应中断的条件是：有来自于中断源的中断请求、CPU允许中断。如果中断响应条件不满足，则中断处理无法进行。
(2) 如果CPU响应中断，则CPU关中断，使其进入不可再次响应中断的状态。
(3) 保存被中断进程现场。为了在中断处理结束后能使进程正确地返回到中断点，系统必须保存当前处理机状态字PSW和程序计数器PC等的值。这些值一般保存在特定堆栈或硬件寄存器中。
(4) 分析中断原因，调用中断处理子程序。在多个中断请求同时发生时，处理优先级最高的中断源发出的中断请求。
(5) 执行中断处理子程序。对陷阱来说，在有些系统中则是通过陷阱指令向当前执行进程发软中断信号后调用对应的处理子程序执行。
(6) 退出中断，恢复被中断进程的现场或调度新进程占据处理机。
(7) 开中断，CPU继续执行。
1．什么叫中断？
简单来说，中断是一种使CPU中止正在执行的程序而转去处理特殊事件的操作。这些引起中断的事件称为中断源，它们可能是来自外设的输入输出请求，也可能是计算机的一些异常事故或其它内部原因。
更具体地，我们定义CPU中断为这样一个过程：在特定的事件（中断源，也称中断请求信号）触发下引起CPU暂停正在运行的程序（主程序），转而先去处理一段为特定事件而编写的处理程序（中断处理程序），等中断处理程序处理完成后，再回到主程序被打断的地方继续运行。
2．中断的作用
一方面，有了中断功能，PC系统就可以使CPU和外设同时工作，使系统可以及时地响应外部事件。而且有了中断功能，CPU可允许多个外设同时工作。这样就大大提高了CPU的利用率，也提高了数据输入、输出的速度。
另一方面，有了中断功能，就可以使CPU及时处理各种软硬件故障。计算机在运行过程中，往往会出现事先预料不到的情况或出现一些故障，如电源掉电、存储出错，运算溢出等等。计算机可以利用中断系统自行处理，而不必停机或报告工作人员。
3．中断类型
在PC机系统中，根据中断源的不同，中断常分为两大类：硬件中断和软件中断。
硬件中断也称为外部中断，它又可以分为两种：
1）．可屏蔽中断：是可以被CPU屏蔽的由中断电路发出的中断请求信号在CPU的INTR端引起的中断，它常常由PC机的外设或一些接口功能产生，如键盘、打印机、串行口等。可屏蔽意味着这类型中断可以在CPU要处理其它紧急操作时，被软件屏蔽或忽略。
2）．非屏蔽中断：是由CPU的NMI端引起的中断，如当系统出现掉电、内存奇偶校验错误等，系统都将使用非屏蔽中断。非屏蔽是指CPU不能用软件指令来禁止对这种中断响应，也就是CPU必须响应由NMI端送来的中断信号。
软件中断，又称为内部中断，是指程序中使用INT中断指令引起的中断。
4．CPU响应中断的条件
除了非屏蔽中断外，其它中断都可以用软件来屏蔽或开放。系统只有具备如下的中断条件，CPU才可能对中断请求进行响应。
1) 设置中断请求触发器
2) 设置中断屏蔽触发器
3) 设置中断允许触发器
5．CPU处理中断过程
当满足了中断的条件后，CPU就会响应中断，转入中断程序处理。具体的工作过程如下所述。
1) 关中断
2) 保留断点
3) 保护现场
4) 给出中断入口，转入相应的中断服务程序
5) 恢复现场
6) 开中断与返回
6．中断冲突
虽然现在Windows操作系统从Win9X开始已经支持即插即用功能，大大简化了用户的操作，但是如果不能认出要安装的新设备，那么自动分配中断时就会产生冲突。现在新的硬件产品层出不穷，各种产品又相互兼容，功能类似，这就导致了操作系统常常不能正确检测出新设备，中断冲突也就不可避免了。
7．中断控制器8259A的结构
Intel 8259A是与8088/8086系列兼容的可编程的中断控制器。后来的微机系统也沿用这种中断机制及其功能，只是因为集成芯片技术的提高，不单独以8259A芯片的形式出现，而是集成到一个叫做"南桥芯片"或"HUB芯片"的芯片里了。
8259A包括以下几个部分：
1）．中断请求寄存器IRR（Interrupt Request Register）：有8条外界中断请求线IR0～IR7，每一条请求线有一个相应的触发器来保存请求信号。
2）．中断服务寄存器ISR（IN Service Register）：保存正在服务的中断。
3）．优先权电路：对保存在IRR中的各个中断请求，经过判断确定最高的优先权，并在中断响应周期把它选通至中断服务寄存器。
4）．中断屏蔽寄存器IMR（Interrupt Mask Register）：寄存器的每一位，可以对IRR中的相应的中断源进行屏蔽。但对于较高优先权的输入线实现屏蔽并不影响较低优先权的输入。
5）．数据总线缓冲器：是8259A与系统数据总线的接口，它是8位的双向三态缓冲器。凡是CPU对8259A编程时的控制字，都是通过它写入8259A的，8259A状态信息，也是通过它读入CPU的；在中断响应周期，8259A送至数据总线的CALL指令或中断向量也是通过它传送的。
6）．读/写控制逻辑：CPU能通过它实现对8259A的读出（状态信号）和写入（初始化编程）。
7）．级连缓冲器：实现8259A芯片之间的级连，使得中断源可由8级扩展至64级。
8）．控制逻辑部分：对芯片内部的工作进行控制，使它按编程的规定工作。
8．8259A的级连
在一个系统中，8259A可以级连，有一个主8259A，若干个从8259A，最多可以有8个从8259A，把中断源扩展到64个。
非 法 传 送 种 种
1．两个操作数的类型不一致 –-----例如源操作数是字节，而目的操作数是字；或相反
• 绝大多数双操作数指令，除非特别说明，目的操作数与源操作数必须类型一致，否则为非法指令 MOV AL , 050AH；非法指令：050Ah为字，而AL为字节
• 寄存器有明确的字节或字类型，有寄存器参与的指令其操作数类型就是寄存器的类型
• 对于存储器单元与立即数同时作为操作数的情况，必须显式指明；
byte ptr 指示字节类型 ， word ptr 指示字类型。
2．两个操作数不能都是存储器 –------传送指令很灵活，但主存之间的直接传送却不允许
• 8086指令系统不允许两个操作数都是存储单元（除串操作指令），要实现这种传送，可通过寄存器间接实现
mov ax , buffer1；ax←buffer1（将buffer1内容送ax）
mov buffer2 , ax；buffer2←ax；这里buffer1和buffer2是两个字变量、；实际表示直接寻址方式
3．段寄存器的操作有一些限制 –----段寄存器属专用寄存器，对他们的操作能力有限
• 不允许立即数传送给段寄存器 MOV DS,100H；非法指令：立即数不能传送段寄存器
• 不允许直接改变CS值 MOV CS,[SI] ；不允许使用的指令
• 不允许段寄存器之间的直接数据传送 MOV DS,ES；非法指令：不允许段寄存器间传送
MOV BL,AX（数据长度不匹配）
MOV DS,2000H(不允许给段存储器用立即数赋值)
MOV CS,AX(禁止用MOV指令给CS赋值)
MOV [AX],[2000H](禁止直接在存储器间传送)
MOV [2000H],20H(数据长度不确切,应改为
MOV BYTE PTR [2000H],20H)
１、（１）状态标志：CF－进位标志，ZF－零标志，SF－符号标志，PF－奇偶标志
OF－溢出标志，AF－辅助进位标志。
（２）控制标志：DF－方向标志，IF－中断允许标志，TF－陷井标志。
２、8086机器代码格式一般是：
操作码 寻址方式 偏移量 立即数。
３、（１）源操作数为立即寻址，目的操作数为寄存器寻址。
（２）源操作数为寄存器相对寻址，目的操作数为寄存器寻址。
（３）源操作数为寄存器寻址，目的操作数为寄存器间接寻址。
（４）源操作数和目的操作数均为固定寻址。
４、此题要求出物理地址，物理地址的计算公式为：
段地址（段首地址）*10H＋偏移地址（有效地址）
（１）源操作数为立即寻址方式，操作数地址就在本条指令中。
（２）源操作数为直接寻址方式，其物理地址为
DS*10H+100H=20100H
（３）源操作数为寄存器间接寻址，其物理地址为
SS*10H+BP=15010H
（４）源操作数为基址变址寻址，其物理地址为
DS*10H+BX+SI+VAL=201E0H
8086 有14个16位寄存器，这14个寄存器按其用途可分为(1)通用寄存器、(2)指令指针、(3)标志寄存器和(4)段寄存器等4类。
(1)通用寄存器有8个, 又可以分成2组,一组是数据寄存器(4个),另一组是指针寄存器及变址寄存器(4个).
数据寄存器分为:
AH&AL＝AX(accumulator)：累加寄存器，常用于运算;在乘除等指令中指定用来存放操作数,另外,所有的I/O指令都使用这一寄存器与外界设备传送数据.
BH&BL＝BX(base)：基址寄存器，常用于地址索引；
CH&CL＝CX(count)：计数寄存器，常用于计数；常用于保存计算值,如在移位指令,循环(loop)和串处理指令中用作隐含的计数器.
DH&DL＝DX(data)：数据寄存器，常用于数据传递。
他们的特点是,这4个16位的寄存器可以分为高8位: AH, BH, CH, DH.以及低八位：AL,BL,CL,DL。这2组8位寄存器可以分别寻址，并单独使用。
另一组是指针寄存器和变址寄存器，包括：
SP（Stack Pointer）：堆栈指针，与SS配合使用，可指向目前的堆栈位置；
BP（Base Pointer）：基址指针寄存器，可用作SS的一个相对基址位置；
SI（Source Index）：源变址寄存器可用来存放相对于DS段之源变址指针；
DI（Destination Index）：目的变址寄存器，可用来存放相对于 ES 段之目的变址指针。
这4个16位寄存器只能按16位进行存取操作，主要用来形成操作数的地址，用于堆栈操作和变址运算中计算操作数的有效地址。
(2) 指令指针IP(Instruction Pointer)
指令指针IP是一个16位专用寄存器，它指向当前需要取出的指令字节，当BIU从内存中取出一个指令字节后，IP就自动加1，指向下一个指令字节。注意，IP指向的是指令地址的段内地址偏移量，又称偏移地址(Offset Address)或有效地址(EA，Effective Address)。
(3)标志寄存器FR(Flag Register)
8086有一个18位的标志寄存器FR，在FR中有意义的有9位，其中6位是状态位，3位是控制位。
OF： 溢出标志位OF用于反映有符号数加减运算所得结果是否溢出。如果运算结果超过当前运算位数所能表示的范围，则称为溢出，OF的值被置为1，否则，OF的值被清为0。
DF：方向标志DF位用来决定在串操作指令执行时有关指针寄存器发生调整的方向。
IF：中断允许标志IF位用来决定CPU是否响应CPU外部的可屏蔽中断发出的中断请求。但不管该标志为何值，CPU都必须响应CPU外部的不可屏蔽中断所发出的中断请求，以及CPU内部产生的中断请求。具体规定如下：
(1)、当IF=1时，CPU可以响应CPU外部的可屏蔽中断发出的中断请求；
(2)、当IF=0时，CPU不响应CPU外部的可屏蔽中断发出的中断请求。
TF：跟踪标志TF。该标志可用于程序调试。TF标志没有专门的指令来设置或清楚。
（1）如果TF=1，则CPU处于单步执行指令的工作方式，此时每执行完一条指令，就显示CPU内各个寄存器的当前值及CPU将要执行的下一条指令。
（2）如果TF=0，则处于连续工作模式。
SF：符号标志SF用来反映运算结果的符号位，它与运算结果的最高位相同。在微机系统中，有符号数采用补码表示法，所以，SF也就反映运算结果的正负号。运算结果为正数时，SF的值为0，否则其值为1。
ZF： 零标志ZF用来反映运算结果是否为0。如果运算结果为0，则其值为1，否则其值为0。在判断运算结果是否为0时，可使用此标志位。
AF：下列情况下，辅助进位标志AF的值被置为1，否则其值为0：
(1)、在字操作时，发生低字节向高字节进位或借位时；
(2)、在字节操作时，发生低4位向高4位进位或借位时。
PF：奇偶标志PF用于反映运算结果中“1”的个数的奇偶性。如果“1”的个数为偶数，则PF的值为1，否则其值为0。
CF：进位标志CF主要用来反映运算是否产生进位或借位。如果运算结果的最高位产生了一个进位或借位，那么，其值为1，否则其值为0。)
4)段寄存器(Segment Register)
为了运用所有的内存空间，8086设定了四个段寄存器，专门用来保存段地址：
CS（Code Segment）：代码段寄存器；
DS（Data Segment）：数据段寄存器；
SS（Stack Segment）：堆栈段寄存器；
ES（Extra Segment）：附加段寄存器。
当一个程序要执行时，就要决定程序代码、数据和堆栈各要用到内存的哪些位置，通过设定段寄存器 CS，DS，SS 来指向这些起始位置。通常是将DS固定，而根据需要修改CS。所以，程序可以在可寻址空间小于64K的情况下被写成任意大小。 所以，程序和其数据组合起来的大小，限制在DS 所指的64K内，这就是COM文件不得大于64K的原因。8086以内存做为战场，用寄存器做为军事基地，以加速工作。
由于16位/32位CPU是微机CPU的两个重要代表，所以，在此只介绍它们内部寄存器的名称及其主要功能。
1、 16位寄存器组
16位CPU所含有的寄存器有
4个数据寄存器(AX、BX、CX和DX)
2个变址和指针寄存器(SI和DI) 2个指针寄存器(SP和BP)
4个段寄存器(ES、CS、SS和DS)
1个指令指针寄存器(IP) 1个标志寄存器(Flags)
2、 32位寄存器组
32位CPU除了包含了先前CPU的所有寄存器，并把通用寄存器、指令指针和标志寄存器从16位扩充成32位之外，还增加了2个16位的段寄存器：FS和GS。
32位CPU所含有的寄存器有
4个数据寄存器(EAX、EBX、ECX和EDX)
2个变址和指针寄存器(ESI和EDI) 2个指针寄存器(ESP和EBP)
6个段寄存器(ES、CS、SS、DS、FS和GS)
1个指令指针寄存器(EIP) 1个标志寄存器(EFlags)
具有一个输入端口和两个输出端口。
宏与子程序的区别
宏和子程序都是为了简化源程序的编写，提高程序的可维护性，但是它们二者之间存在着以下本质的区别：
1、在源程序中，通过书写宏名来引用宏，而子程序是通过CALL指令来调用；
2、汇编程序对宏通过宏扩展来加入其定义体，宏引用多少次，就相应扩展多少次，所以，引用宏不会缩短目标程序；而子程序代码在目标程序中只出现一次，调用子程序是执行同一程序段，因此，目标程序也得到相应的简化；
3、宏引用时，参数是通过“实参”替换“形参”的方式来实现传递的，参数形式灵活多样，而子程序调用时，参数是通过寄存器、堆栈或约定存储单元进行传递的；
4、宏引用语句扩展后，目标程序中就不再有宏引用语句，运行时，不会有额外的时间开销，而子程序的调用在目标程序中仍存在，子程序的调用和返回均需要时间。
总之，当程序片段不长，速度是关键因素时，可采用宏来简化源程序，但当程序片段较长，存储空间是关键因素时，可采用子程序的方法来简化源程序和目标程序。
DATA SEGMENT
MSG1 DB
MSG2 DW
DATA ANDS
CODE SEGMENT
ASSUME CS:CODE，DS:DATA
START:MOV AX, DATA
MOV DS, AX
MOV DX OFFSET MSG1
( MOV BX
MOV AH, 4CH
INT 21H
CODE ENDS
END START
关于assume的作用，许多人都简单的解释说，这是告诉编译器哪一个段和哪一个段寄存器相关联。举个简单例子来说：
assume cs:code, ds:data
这是告诉编译器cs和code关联，ds和data关联，后来又看到这样的代码
mov ax, data
mov ds, ax
让许多人一头雾水，既然ds和data关联了，怎么又要把data的值送到ds，这到底是怎么回事？
这里，先不做过多的说明，我们先看看下面这个例子：
下面的程序，把data段中的字符串拷贝到dseg段中，并且调用dos的21h中断的9号功能来显示
dseg段中的字符串：
;segtest.asm
data segment
msg db ‘Hello, how are you ?‘, 0dh, 0ah, 24h
data ends
dseg segment
hello db 32 dup(0)
db 0dh, 0ah, 24h
dseg ends
code segment
assume cs:code, ds:dseg, es:data
start:
mov ax, dseg
mov ds, ax ; 把dseg段的段地址送入ds
mov ax, data
mov es, ax ; 把data段的段地址送入es
mov si, offset msg ; 把源字符串的偏移送入si
mov di, offset hello ; 把目标字符串的偏移送入di
cploop:
mov al, msg[si]; (1)这里是一个寄存器相对寻址，那么这个物理地址是怎么形成的呢？
cmp al, 24h
jz ok
mov hello[di], al; (2)这里又是一个寄存器相对寻址，这个物理地址又是怎么形成的？
inc si
inc di
jmp short cploop
ok:
mov dx, offset hello
mov ah, 9h
int 21h
mov ax, 4c00h
int 21h
code ends
end start
对于（1）和（2）中两个地址的形成我们来分析一下：
这两个都是寄存器相对寻址，即有效地址都是一个寄存器加上一个16位的偏移量
对于（1） EA = (si) + msg的偏移地址
物理地址就是: (段寄存器)×16+EA
段寄存器有四个cs, ds, es, ss, 那么编译器怎么知道用哪一个呢？ 这里就显示出了assume的作用，是assume告诉了编译器,data段中的标号的段地址要从es中取得，即这一句：
es:data 告诉了编译器在data segment和data ends之间的所有的标号都要使用es作为段寄存器来寻址，于是当编译器看到这个msg标号的时候，它就知道了这里物理地址的形成是用(es)×16+EA
同理，对于（2），当编译器看到hello这个标号的时候，它就知道要取ds中的值作为段地址。如果没有
assume说明哪一个段和哪一个寄存器关联，那么，编译器就无法确定到底用哪一个段寄存器来计算物理地址。
从这里，我们也可以看出，assume的作用仅仅是告诉编译器，我碰到一个标号，要计算它的物理地址的时候，从哪一个段寄存器里面取出段值，至于这个段寄存器的值对不对，那它就不管了，这是程序员的事情，反正它只管根据assume里面的设定来用段寄存器，所以，对于程序员来说，不仅要用assume告诉编译器计算物理地址的时候要从哪一个段寄存器取值，而且要在指令中明确的把对应段的段值送到设定好的段寄存器中。
用伪指令assume告诉编译器，data段中的标号的段地址要从es中取值，而指令
mov ax, data
mov es, ax
则把data段的段地址送入es中，这样编译器计算msg标号的物理地址的时候，才能得到正确的段地址。
当然，如果你不用assume指明哪一个段和哪一个寄存器相关联，比如我把assume cs:code, ds:dseg, es:data改为
assume cs:code这也可以，即我不把ds和dseg关联，也不把es和data关联，但是你必须在指令中明确的告诉编译器使用哪一个段寄存器
指令mov al, msg[si]必须改为 mov al, es:msg[si]， 而指令mov hello[di], al也必须改为mov ds:hello[di], al，这样编译器才能知道使用哪一个段寄存器计算物理地址。如果编译器无法确定标号的段地址，那么程序编译就不会通过。
标签：操作 中断方式 寻址 结构 优先级 主程序 匹配 左移 tle
原文地址：https://www.cnblogs.com/Sumarua/p/11698360.html
