标签：
自己写过Vertex & Fragment Shader的童鞋，大概都会对Unity的光照痛恨不已。当然，我相信这是因为我们写得少。。。不过这也是由于官方文档对这方面介绍很少的缘故，导致我们无法自如地处理很多常见的光照变量。这篇我们就来讨论下Unity内置的一些光照变量和函数到底怎么用。
以下内容均建立在Forward Rendering Path的基础上。
自己总结的，如果有硬伤一定要告诉我啊！感激不尽~
主要参考：
在开始后面的讨论之前，先要弄懂一个问题就是Unity可以在Forward Rendering Path中可以处理哪些以及处理多少光照。这里只提取官方文档中的一些内容加以说明。
在Forward Rendering中，有三种处理光照（即照亮物体）的方式：逐顶点处理，逐像素处理，球谐函数（Spherical Harmonics，SH）处理。而决定一个灯光是哪种处理模式取决于它的类型和模式：
那在哪里进行光照处理呢？当然是在Pass里。Forward Rendering有两种Pass：Base Pass，Additional Passes。这两种Pass的图例说明如下：
注意其中的Per-Vertex Lights/SH Lights前面我标注了可选的，这是说，我们可以选择是否处理这些光源。如果我们没有在Base Pass中写明相关的处理函数，那么这些光源实际上不会对物体产生影响。另一点就是其中橘黄色字表明的代码，其中Tags我就不赘述了，这是基本要求。“#pragma multi_compile_fwdbase”这种在长久的实验中表明最好是写上它们，这会让一些函数和宏可以正确工作，很可惜，现在官方没有给出明确的文档说明，因此我们还是乖乖地每次都加上它们比较好。最后，注意对于Forward Rendering来说，只有Bass Pass中处理的第一个平行光可以有阴影效果。
从上面的图中，我们已经知道，由于逐像素的光源是最重要的一种光源，因此Unity会花费一整个Pass来处理它。而对于逐顶点/SH光源来说，它们都将会在Bass Pass中处理（和最重要的平行光一起）。没分量就是这种结果。那么，Base Pass会说，“我这么小就让我做这么多东西，平行光就一个数量少就算了，SH光工作量少也算了，但顶点光也来捣乱我就不干了，不行！我得有条件！”于是Unity规定说，最多只有4个光源会按照逐顶点光源来处理，其他只能按SH光源处理。
这里很容易就弄混弄蒙了。我们先来看官方给的情况，即第一种情况：所有光源都被设置成Auto。这种情况下，Unity会自动为光源选择合适的类型。这时，有一个项目设置很重要就是Pixel Light Count，它决定了逐像素光的最大数目。当Pixel Light Count为4时，就是那张著名的图例情况（来自官方文档）：
上面的类型选择过程大概是这样的：首先，前Pixel Light Count（这里是4）个光源会按照逐像素进行处理，然后最多4个逐顶点光源，剩下的就是SH光了。其中，注意每种光源之间会有重叠的情况，这主要是为了防止物体移动时光照产生突变。
但是，如果光源没有被设置为Auto，而是被指明是Important和Not Important，又会怎样呢？（不要问我有的被设置成Auto，有的设置成Important会怎样，你这人真讨厌自己分析吧。。。）那么，第二种情况：自定义光源类型。首先，记住一点，这时不再受Pixel Light Count的限制，那么被设置成Important全部会被当成逐像素光源，一个不剩；如果被设置成Not Important，那么最多有4个光源会被当成逐顶点光源，其他就会被当做SH光源进行处理。
上面听起来很复杂，其实就是个“物竞天择”的过程。我们可以想象，所有的光源都在争抢更多的计算资源，都想让自己成为最重要的逐像素光，再不济点就逐顶点光，要是实在混的不好就只能当成SH光了。那么挣到了资源又怎么处理呢？对于逐像素光，它有一整个Pass的资源可以挥霍，而这里会涉及到各种光照变量和函数的使用，后面会讲；对于逐顶点光和SH光来说，很可惜，Unity并没有明确的文档来告诉我们如何访问它们，我们只能通过UnityShaderVariables.cginc中的变量声明和Surface Shader的编译结果来“揣测”用法。这也是后面讲的内容。
吐槽时间：虽然文档上这么写，但实际过程中还是有很多莫名其妙的问题：
在UnityShaderVariables.cginc文件中，我们可以找到Unity提供的和处理光照有关的变量：
CBUFFER_START(UnityLighting) #ifdef USING_DIRECTIONAL_LIGHT uniform fixed4 _WorldSpaceLightPos0; #else uniform float4 _WorldSpaceLightPos0; #endif uniform float4 _LightPositionRange; // xyz = pos, w = 1/range // Built-in uniforms for "vertex lights" float4 unity_4LightPosX0; // x coordinates of the 4 light sources in world space float4 unity_4LightPosY0; // y coordinates of the 4 light sources in world space float4 unity_4LightPosZ0; // z coordinates of the 4 light sources in world space float4 unity_4LightAtten0; // scale factors for attenuation with squared distance float4 unity_LightColor[8]; // array of the colors of the 4 light sources float4 unity_LightPosition[8]; // apparently is not always correctly set // x = -1 // y = 1 // z = quadratic attenuation // w = range^2 float4 unity_LightAtten[8]; // apparently is not always correctly set float4 unity_SpotDirection[8]; // SH lighting environment float4 unity_SHAr; float4 unity_SHAg; float4 unity_SHAb; float4 unity_SHBr; float4 unity_SHBg; float4 unity_SHBb; float4 unity_SHC; CBUFFER_END
在UnityCG.cginc可以找到光照处理辅助函数：
// Computes world space light direction inline float3 WorldSpaceLightDir( in float4 v ); // Computes object space light direction inline float3 ObjSpaceLightDir( in float4 v ); // Computes world space view direction inline float3 WorldSpaceViewDir( in float4 v ); // Computes object space view direction inline float3 ObjSpaceViewDir( in float4 v ); float3 Shade4PointLights ( float4 lightPosX, float4 lightPosY, float4 lightPosZ, float3 lightColor0, float3 lightColor1, float3 lightColor2, float3 lightColor3, float4 lightAttenSq, float3 pos, float3 normal); float3 ShadeVertexLights (float4 vertex, float3 normal); // normal should be normalized, w=1.0 half3 ShadeSH9 (half4 normal);
下面我们来看下如何在两种Pass中使用上面的变量和函数处理不同类型的光照。
下面的讨论主要建立在下面的代码下，可以先扫一遍，这里不用细看。它主要计算了漫反射光照和高光反射光照，还示例了逐顶点光源和SH光源的计算等。
Shader "Light Test" {
Properties {
_Color ("Color", color) = (1.0,1.0,1.0,1.0)
}
SubShader {
Tags { "RenderType"="Opaque"}
Pass {
Tags { "LightMode"="ForwardBase"} // pass for 4 vertex lights, ambient light & first pixel light (directional light)
CGPROGRAM
// Apparently need to add this declaration
#pragma multi_compile_fwdbase
#pragma vertex vert
#pragma fragment frag
#include "UnityCG.cginc"
#include "Lighting.cginc"
#include "AutoLight.cginc"
uniform float4 _Color;
struct vertexInput {
float4 vertex : POSITION;
float3 normal : NORMAL;
};
struct vertexOutput {
float4 pos : SV_POSITION;
float4 posWorld : TEXCOORD0;
float3 normalDir : TEXCOORD1;
float3 lightDir : TEXCOORD2;
float3 viewDir : TEXCOORD3;
float3 vertexLighting : TEXCOORD4;
LIGHTING_COORDS(5, 6)
};
vertexOutput vert(vertexInput input) {
vertexOutput output;
output.pos = mul(UNITY_MATRIX_MVP, input.vertex);
output.posWorld = mul(_Object2World, input.vertex);
output.normalDir = normalize(mul(float4(input.normal, 0.0), _World2Object).xyz);
output.lightDir = WorldSpaceLightDir(input.vertex);
output.viewDir = WorldSpaceViewDir(input.vertex);
output.vertexLighting = float3(0.0);
// SH/ambient and vertex lights
#ifdef LIGHTMAP_OFF
float3 shLight = ShadeSH9 (float4(output.normalDir, 1.0));
output.vertexLighting = shLight;
#ifdef VERTEXLIGHT_ON
float3 vertexLight = Shade4PointLights (
unity_4LightPosX0, unity_4LightPosY0, unity_4LightPosZ0,
unity_LightColor[0].rgb, unity_LightColor[1].rgb, unity_LightColor[2].rgb, unity_LightColor[3].rgb,
unity_4LightAtten0, output.posWorld, output.normalDir);
output.vertexLighting += vertexLight;
#endif // VERTEXLIGHT_ON
#endif // LIGHTMAP_OFF
// pass lighting information to pixel shader
TRANSFER_VERTEX_TO_FRAGMENT(output);
return output;
}
float4 frag(vertexOutput input):COLOR{
float3 normalDirection = normalize(input.normalDir);
float3 viewDirection = normalize(_WorldSpaceCameraPos - input.posWorld.xyz);
float3 lightDirection;
float attenuation;
if (0.0 == _WorldSpaceLightPos0.w) // directional light?
{
attenuation = 1.0; // no attenuation
lightDirection = normalize(_WorldSpaceLightPos0.xyz);
}
else // point or spot light
{
float3 vertexToLightSource = _WorldSpaceLightPos0.xyz - input.posWorld.xyz;
float distance = length(vertexToLightSource);
attenuation = 1.0 / distance; // linear attenuation
lightDirection = normalize(vertexToLightSource);
}
// LIGHT_ATTENUATION not only compute attenuation, but also shadow infos
// attenuation = LIGHT_ATTENUATION(input);
// Compare to directions computed from vertex
// viewDirection = normalize(input.viewDir);
// lightDirection = normalize(input.lightDir);
// Because SH lights contain ambient, we don‘t need to add it to the final result
float3 ambientLighting = UNITY_LIGHTMODEL_AMBIENT.xyz;
float3 diffuseReflection = attenuation * _LightColor0.rgb * _Color.rgb * max(0.0, dot(normalDirection, lightDirection)) * 2;
float3 specularReflection;
if (dot(normalDirection, lightDirection) < 0.0) // light source on the wrong side?
{
specularReflection = float3(0.0, 0.0, 0.0); // no specular reflection
}
else // light source on the right side
{
specularReflection = attenuation * _LightColor0.rgb * _Color.rgb * pow(max(0.0, dot(reflect(-lightDirection, normalDirection), viewDirection)), 255);
}
return float4(input.vertexLighting + diffuseReflection + specularReflection, 1.0);
}
ENDCG
}
Pass{
Tags { "LightMode"="ForwardAdd"} // pass for additional light sources
ZWrite Off Blend One One Fog { Color (0,0,0,0) } // additive blending
CGPROGRAM
// Apparently need to add this declaration
#pragma multi_compile_fwdadd
#pragma vertex vert
#pragma fragment frag
#include "UnityCG.cginc"
#include "Lighting.cginc"
#include "AutoLight.cginc"
uniform float4 _Color;
struct vertexInput {
float4 vertex : POSITION;
float3 normal : NORMAL;
};
struct vertexOutput {
float4 pos : SV_POSITION;
float4 posWorld : TEXCOORD0;
float3 normalDir : TEXCOORD1;
float3 lightDir : TEXCOORD2;
float3 viewDir : TEXCOORD3;
LIGHTING_COORDS(4, 5)
};
vertexOutput vert(vertexInput input) {
vertexOutput output;
output.pos = mul(UNITY_MATRIX_MVP, input.vertex);
output.posWorld = mul(_Object2World, input.vertex);
output.normalDir = normalize(mul(float4(input.normal, 0.0), _World2Object).xyz);
output.lightDir = WorldSpaceLightDir(input.vertex);
output.viewDir = WorldSpaceViewDir(input.vertex);
// pass lighting information to pixel shader
vertexInput v = input;
TRANSFER_VERTEX_TO_FRAGMENT(output);
return output;
}
float4 frag(vertexOutput input):COLOR{
float3 normalDirection = normalize(input.normalDir);
float3 viewDirection = normalize(_WorldSpaceCameraPos - input.posWorld.xyz);
float3 lightDirection;
float attenuation;
if (0.0 == _WorldSpaceLightPos0.w) // directional light?
{
attenuation = 1.0; // no attenuation
lightDirection = normalize(_WorldSpaceLightPos0.xyz);
}
else // point or spot light
{
float3 vertexToLightSource = _WorldSpaceLightPos0.xyz - input.posWorld.xyz;
float distance = length(vertexToLightSource);
attenuation = 1.0 / distance; // linear attenuation
lightDirection = normalize(vertexToLightSource);
}
// LIGHT_ATTENUATION not only compute attenuation, but also shadow infos
// attenuation = LIGHT_ATTENUATION(input);
// Compare to directions computed from vertex
// viewDirection = normalize(input.viewDir);
// lightDirection = normalize(input.lightDir);
float3 diffuseReflection = attenuation * _LightColor0.rgb * _Color.rgb * max(0.0, dot(normalDirection, lightDirection)) * 2;
float3 specularReflection;
if (dot(normalDirection, lightDirection) < 0.0) // light source on the wrong side?
{
specularReflection = float3(0.0, 0.0, 0.0); // no specular reflection
}
else // light source on the right side
{
specularReflection = attenuation * _LightColor0.rgb * _Color.rgb * pow(max(0.0, dot(reflect(-lightDirection, normalDirection), viewDirection)), 255);
}
return float4(diffuseReflection + specularReflection, 1.0);
}
ENDCG
}
}
FallBack "Diffuse"
}回想一下，上面我们说过在Bass Pass中，我们可以处理全部三种光照：处理第一个平行光作为逐像素光处理，处理所有的逐顶点光，处理其他所有SH光。还有很重要的一点就是，我们还要处理环境光、阴影等。一句话，由于Additional Passes只能处理逐像素光，如果你想要其他光照效果，都需要在Bass Pass中处理。
这里的环境光指的是我们在Edit->Render Setting里面的Ambient Light的值。在Shader中获取它很容易，只需要访问全局变量UNITY_LIGHTMODEL_AMBIENT即可。它是全局变量，因此在在哪个Pass里访问都可以，但环境光只需要加一次即可，因此我们只需要在Bass Pass中叠加到其他颜色上即可。
Base Pass还有一个非常重要的作用就是添加阴影。上面提到过，对于Forward Rendering来说，只有Bass Pass中处理的第一个平行光可以有阴影效果。也就是说，错过了这里就不会得到阴影信息了。程序中模拟阴影主要是依靠一张Shadow Map，里面记录了从光源出发距离它最近的深度信息。Unity很贴心地提供了这样的一张纹理（_ShadowMapTexture），不用我们自己再编程实现了。
与阴影的实现类似，Unity还提供了一张纹理（_LightTexture0），这张纹理包含了光照衰减（attenuation）。
由于阴影和光照衰减都是对纹理进行采样，然后将结果乘以颜色值，因此Unity把这两步合并到一个宏中，让我们通过一个宏调用就可以解决这两个问题。既然是对纹理采样，那么首先就要知道顶点对应的纹理坐标，Unity同样是通过宏来辅助我们完成的，我们只需要在v2f（vertexOutput）中添加关于宏LIGHTING_COORDS即可。然后，为了计算顶点对应的两张纹理上的坐标，需要在vert函数里面调用一个新的宏：TRANSFER_VERTEX_TO_FRAGMENT。
这个过程中使用的宏定义都在AutoLight.cginc文件中。
一个完整的过程如下：
Tags { "LightMode"="ForwardBase"} // pass for 4 vertex lights, ambient light & first pixel light (directional light)
CGPROGRAM
// Apparently need to add this declaration
#pragma multi_compile_fwdbase struct vertexOutput {
float4 pos : SV_POSITION;
float4 posWorld : TEXCOORD0;
float3 normalDir : TEXCOORD1;
float3 lightDir : TEXCOORD2;
float3 viewDir : TEXCOORD3;
float3 vertexLighting : TEXCOORD4;
LIGHTING_COORDS(5, 6)
}; vertexOutput vert(vertexInput input) {
vertexOutput output;
......
// pass lighting information to pixel shader
vertexInput v = input;
TRANSFER_VERTEX_TO_FRAGMENT(output);
return output;
}attenuation = LIGHT_ATTENUATION(input);
#ifdef POINT #define LIGHTING_COORDS(idx1,idx2) float3 _LightCoord : TEXCOORD##idx1; SHADOW_COORDS(idx2) uniform sampler2D _LightTexture0; uniform float4x4 _LightMatrix0; #define TRANSFER_VERTEX_TO_FRAGMENT(a) a._LightCoord = mul(_LightMatrix0, mul(_Object2World, v.vertex)).xyz; TRANSFER_SHADOW(a) #define LIGHT_ATTENUATION(a) (tex2D(_LightTexture0, dot(a._LightCoord,a._LightCoord).rr).UNITY_ATTEN_CHANNEL * SHADOW_ATTENUATION(a)) #endif #ifdef DIRECTIONAL #define LIGHTING_COORDS(idx1,idx2) SHADOW_COORDS(idx1) #define TRANSFER_VERTEX_TO_FRAGMENT(a) TRANSFER_SHADOW(a) #define LIGHT_ATTENUATION(a) SHADOW_ATTENUATION(a) #endif
#define SHADOW_COORDS(idx1) float4 _ShadowCoord : TEXCOORD##idx1; #define TRANSFER_SHADOW(a) a._ShadowCoord = mul (unity_World2Shadow[0], mul(_Object2World,v.vertex)); #define SHADOW_ATTENUATION(a) unitySampleShadow(a._ShadowCoord)
uniform float4 unity_4LightPosX0; // x coordinates of the 4 light sources in world space uniform float4 unity_4LightPosY0; // y coordinates of the 4 light sources in world space uniform float4 unity_4LightPosZ0; // z coordinates of the 4 light sources in world space uniform float4 unity_4LightAtten0; // scale factors for attenuation with squared distance
float3 Shade4PointLights (
float4 lightPosX, float4 lightPosY, float4 lightPosZ,
float3 lightColor0, float3 lightColor1, float3 lightColor2, float3 lightColor3,
float4 lightAttenSq,
float3 pos, float3 normal)
{
// to light vectors
float4 toLightX = lightPosX - pos.x;
float4 toLightY = lightPosY - pos.y;
float4 toLightZ = lightPosZ - pos.z;
// squared lengths
float4 lengthSq = 0;
lengthSq += toLightX * toLightX;
lengthSq += toLightY * toLightY;
lengthSq += toLightZ * toLightZ;
// NdotL
float4 ndotl = 0;
ndotl += toLightX * normal.x;
ndotl += toLightY * normal.y;
ndotl += toLightZ * normal.z;
// correct NdotL
float4 corr = rsqrt(lengthSq);
ndotl = max (float4(0,0,0,0), ndotl * corr);
// attenuation
float4 atten = 1.0 / (1.0 + lengthSq * lightAttenSq);
float4 diff = ndotl * atten;
// final color
float3 col = 0;
col += lightColor0 * diff.x;
col += lightColor1 * diff.y;
col += lightColor2 * diff.z;
col += lightColor3 * diff.w;
return col;
}float3 vertexLight = Shade4PointLights ( unity_4LightPosX0, unity_4LightPosY0, unity_4LightPosZ0, unity_LightColor[0].rgb, unity_LightColor[1].rgb, unity_LightColor[2].rgb, unity_LightColor[3].rgb, unity_4LightAtten0, output.posWorld, output.normalDir);
float4 unity_LightPosition[8]; // apparently is not always correctly set
// x = -1
// y = 1
// z = quadratic attenuation
// w = range^2
float4 unity_LightAtten[8]; // apparently is not always correctly set
float4 unity_SpotDirection[8];float3 ShadeVertexLights (float4 vertex, float3 normal)
{
float3 viewpos = mul (UNITY_MATRIX_MV, vertex).xyz;
float3 viewN = mul ((float3x3)UNITY_MATRIX_IT_MV, normal);
float3 lightColor = UNITY_LIGHTMODEL_AMBIENT.xyz;
for (int i = 0; i < 4; i++) {
float3 toLight = unity_LightPosition[i].xyz - viewpos.xyz * unity_LightPosition[i].w;
float lengthSq = dot(toLight, toLight);
float atten = 1.0 / (1.0 + lengthSq * unity_LightAtten[i].z);
float diff = max (0, dot (viewN, normalize(toLight)));
lightColor += unity_LightColor[i].rgb * (diff * atten);
}
return lightColor;
}vertexLight = ShadeVertexLights(input.vertex, input.normal)
These functions are only useful when using forward rendering (ForwardBase or ForwardAdd pass types).
float3 Shade4PointLights (...) - computes illumination from four point lights, with light data tightly packed into vectors. Forward rendering uses this to compute per-vertex lighting.These functions are only useful when using per-vertex lit shaders (“Vertex” pass type).
float3 ShadeVertexLights (float4 vertex, float3 normal) - computes illumination from four per-vertex lights and ambient, given object space position & normal.
那些既不是逐像素光又不是逐顶点光的光源，如果想对物体产生影响，就只能按SH光照进行处理。宫斗失败就是这个结果。Unity里和计算SH光有关的变量和函数如下：
// SH lighting environment float4 unity_SHAr; float4 unity_SHAg; float4 unity_SHAb; float4 unity_SHBr; float4 unity_SHBg; float4 unity_SHBb; float4 unity_SHC;
// normal should be normalized, w=1.0
half3 ShadeSH9 (half4 normal)
{
half3 x1, x2, x3;
// Linear + constant polynomial terms
x1.r = dot(unity_SHAr,normal);
x1.g = dot(unity_SHAg,normal);
x1.b = dot(unity_SHAb,normal);
// 4 of the quadratic polynomials
half4 vB = normal.xyzz * normal.yzzx;
x2.r = dot(unity_SHBr,vB);
x2.g = dot(unity_SHBg,vB);
x2.b = dot(unity_SHBb,vB);
// Final quadratic polynomial
float vC = normal.x*normal.x - normal.y*normal.y;
x3 = unity_SHC.rgb * vC;
return x1 + x2 + x3;
} float3 shLight = ShadeSH9 (float4(output.normalDir, 1.0));
我们以之前的例子为例，看一下只输出SH光照的结果。下面左图中，是只有四个光源的情况，可以看出此时并没有任何SH光，这是因为这四个光源此时被当做是逐顶点光照。这里物体颜色非黑是因为unity_SHAr、unity_SHAg、unity_SHAb包含了环境光数据，而非真正的光照造成的，因此理论上只要包含了计算SH光照的代码就不需要在最后结果上添加上面提到的环境光了。右图则是增加了4个新的Not Important光源后的SH光照结果。
我们将逐顶点光照和SH光照结合在一起，代码如下：
// SH/ambient and vertex lights #ifdef LIGHTMAP_OFF float3 shLight = ShadeSH9 (float4(output.normalDir, 1.0)); output.vertexLighting = shLight; #ifdef VERTEXLIGHT_ON float3 vertexLight = Shade4PointLights ( unity_4LightPosX0, unity_4LightPosY0, unity_4LightPosZ0, unity_LightColor[0].rgb, unity_LightColor[1].rgb, unity_LightColor[2].rgb, unity_LightColor[3].rgb, unity_4LightAtten0, output.posWorld, output.normalDir); output.vertexLighting += vertexLight; #endif // VERTEXLIGHT_ON #endif // LIGHTMAP_OFF
我们把两者相加的结果输出，可以得到以下的结果：
最后，我们来谈谈Additional Passes中的逐像素光。我们需要知道的是，其实在Base Pass中我们也需要处理逐像素光，但我们可以明确的知道这个逐像素光只能是第一个平行光。而在Additional Passes中，逐像素光可能是平行光、点光源、聚光灯光源（Spot Light）。这里不讨论使用了LightMap或者开启了Cookie的情况。
同样，这里的逐像素光其实也只是一个名字，Unity只是负责把所谓的逐像素光的数据放到一些变量中，但是，没有什么可以阻止我们是在vert中计算还是在frag中计算。
注意：想要Additional Passes是叠加在Bass Pass上的话（一般人的目的都是这个），请确保你给Pass添加了合适的混合模式。例如：
Pass{
Tags { "LightMode"="ForwardAdd"} // pass for additional light sources
ZWrite Off Blend One One Fog { Color (0,0,0,0) } // additive blending对于逐像素光照，我们最长使用的变量和函数如下：
来自UnityShaderVariables.cginc：
uniform float4 _WorldSpaceLightPos0; uniform float3 _WorldSpaceCameraPos;
来自Lighting.cginc：
fixed4 _LightColor0;
// Computes world space light direction inline float3 WorldSpaceLightDir( in float4 v ); // Computes object space light direction inline float3 ObjSpaceLightDir( in float4 v ); // Computes world space view direction inline float3 WorldSpaceViewDir( in float4 v ); // Computes object space view direction inline float3 ObjSpaceViewDir( in float4 v );
我们先不管这些变量和函数，先来想想我们到底想利用逐像素光照来计算什么，在哪里计算。最常见的需求就是计算光源方向和视角方向，然后再进行漫反射和高光反射的计算。在Unity里在哪里计算这些方向似乎从视觉上没有太大的区别，理论上在vert中计算比在frag中计算更快一点。但计算位置的选择决定了我们可以如何使用上面的变量和函数。
可以注意到，Unity提供的函数都是在vert函数中的辅助函数，即都是只需要提供顶点位置就可以得到光照方向和视角方向的。也就是说，如果我们想要在vert函数中就计算各个方向的值，可以这么做：
output.lightDir = WorldSpaceLightDir(input.vertex); output.viewDir = WorldSpaceViewDir(input.vertex);
// Computes world space light direction
inline float3 WorldSpaceLightDir( in float4 v )
{
float3 worldPos = mul(_Object2World, v).xyz;
#ifndef USING_LIGHT_MULTI_COMPILE
return _WorldSpaceLightPos0.xyz - worldPos * _WorldSpaceLightPos0.w;
#else
#ifndef USING_DIRECTIONAL_LIGHT
return _WorldSpaceLightPos0.xyz - worldPos;
#else
return _WorldSpaceLightPos0.xyz;
#endif
#endif
} if (0.0 == _WorldSpaceLightPos0.w) // directional light?
{
attenuation = 1.0; // no attenuation
lightDirection = normalize(_WorldSpaceLightPos0.xyz);
}
else // point or spot light
{
float3 vertexToLightSource = _WorldSpaceLightPos0.xyz - input.posWorld.xyz;
lightDirection = normalize(vertexToLightSource);
}_LightColor0就没什么可说的了，就是存储了该逐像素光的颜色。
今天就到这里。
标签：
原文地址：http://blog.csdn.net/candycat1992/article/details/42460959
