Inno Setup 教程

; 脚本由 Inno Setup 脚本向导 生成！
; 有关创建 Inno Setup 脚本文件的详细资料请查阅帮助文档！

#define MyAppName "xxxxxxxx"
#define MyAppName1 "xxxxxx"
#define MyAppName2 "xxxxxx"
#define MyAppVersion "1.00"
#define MyAppPublisher "xxx"
#define MyAppURL "http://www.xxx.com/"
#define MyAppExeName1 "xxxx.exe"
#define MyAppExeName2 "xxxx.exe"


;这个段包含用于安装程序和卸载程序的全局设置
[Setup]
; 注: AppId的值为单独标识该应用程序。
; 不要为其他安装程序使用相同的AppId值。
; (生成新的GUID，点击 工具|在IDE中生成GUID。)
AppId={{CF002CA5-9C74-491C-AF38-903CD91BF624}
;安装界面左上角程序名
AppName={#MyAppName}
AppVersion={#MyAppVersion}
;AppVerName={#MyAppName} {#MyAppVersion}

;默认安装目录、默认安装目录名
DefaultDirName={pf}\{#MyAppName}
DefaultGroupName={#MyAppName}
;选择是否创建图标
AllowNoIcons=1
;是否进行选择安装模式
AlwaysShowComponentsList=1
;设置开始菜单文件夹名
AlwaysShowGroupOnReadyPage=1
AppCopyright=Copyright 2015 xxx
AppPublisher={#MyAppPublisher}
AppPublisherURL={#MyAppURL}
AppSupportURL={#MyAppURL}

;可重新修复软件
;AppModifyPath="{app}\Setup.exe"/modify=1
;资源管理器更改环境变量
;ChangesEnvironment=1
;提示输入用户信息
;UserInfoPage=1
;默认序列号
;DefaultUserInfoSerial=serial
;密码
;Password=pwd
;许可文档
;LicenseFile=license.txt
;选择目标目录页签显示阅读文档
;InfoBeforeFile=infobefore.txt
;安装完成后显示阅读文档
;InfoAfterFile=infoafter.txt
;显示启动渐变背景
;WindowVisible=1
;安装程序使用“3D”选择框
FlatComponentsList=0
;安装程序指定新图标
SetupIconFile=F:\xxx\xxx.ico
;卸载图标
;UninstallDisplayIcon={app}\uninstall.ico

OutputDir=F:\xxx
OutputBaseFilename=xxx
Compression=lzma
SolidCompression=yes

;可选。用来定义安装程序向导在选择组件面时可供选择的所有安装类型
[Types]
Name:"communication";Description:xxxx
Name:"client";Description:xxxx

;可选。定义安装程序向导的选择组件页中显示的所有组件，以便于用户定制安装类型
[Components]
Name:"communication";Description:{#MyAppName1};Types:communication
Name:"client";Description:{#MyAppName2};Types:client

[Languages]
Name: "chinesesimp"; MessagesFile: "compiler:Default.isl"
Name:"en";MessagesFile:"compiler:English.isl"

;可选。定义安装程序在执行安装期间所有由用户定制的任务。
[Tasks]
Name: "desktopicon"; Description: "{cm:CreateDesktopIcon}"; GroupDescription: "{cm:AdditionalIcons}"; Flags: unchecked; OnlyBelowVersion: 0,6.1

;定义安装程序安装文件到用户系统中的可选文段
[Files]
Source: "F:\xxx\xxx\xxx.exe"; DestDir: "{app}"; Flags: ignoreversion;Components:communication
Source: "F:\xxx\xxx\xxx.exe.config"; DestDir: "{app}"; Flags: ignoreversion ;Components:communication
Source: "F:\xxx\xxx\xxx.exe"; DestDir: "{app}"; Flags: ignoreversion;Components:client
Source: "F:\xxx\xxx\xxx.exe.config"; DestDir: "{app}"; Flags: ignoreversion ;Components:client


; 注意: 不要在任何共享系统文件上使用“Flags: ignoreversion”

;定义所有创建在开始菜单和/或其他位置的快捷方式

; Add the ISSkin DLL used for skinning Inno Setup installations.
Source: compiler:ISSkin.dll; DestDir: {app}; Flags: dontcopy
; Add the Visual Style resource contains resources used for skinning,
; you can also use Microsoft Visual Styles (*.msstyles) resources.
Source: compiler:IsSkins\Codejock.cjstyles; DestDir: {tmp}; Flags: dontcopy

[Code]



// Importing LoadSkin API from ISSkin.DLL
procedure LoadSkin(lpszPath: AnsiString; lpszIniFileName: AnsiString);
external ‘LoadSkin@files:isskin.dll stdcall‘;

// Importing UnloadSkin API from ISSkin.DLL
procedure UnloadSkin();
external ‘UnloadSkin@files:isskin.dll stdcall‘;

// Importing ShowWindow Windows API from User32.DLL
function ShowWindow(hWnd: Integer; uType: Integer): Integer;
external ‘ShowWindow@user32.dll stdcall‘;

function InitializeSetup(): Boolean;
var Path:string ;
    ResultCode: Integer;
    dotNetV4RegPath:string;
    dotNetV4PackFile:string;
begin
    ExtractTemporaryFile(‘Codejock.cjstyles‘);
    LoadSkin(AnsiString(ExpandConstant(‘{tmp}\Codejock.cjstyles‘)), ‘‘);
    //Result := True;

  dotNetV4RegPath:=‘SOFTWARE\Microsoft\NET Framework Setup\NDP\v4\Full‘;
  dotNetV4PackFile:=‘{src}\dotNetFx40_Full_x86_x64.exe‘;

  if RegKeyExists(HKLM, dotNetV4RegPath) then
  begin
    Result := true;
  end
  else
  begin
      Path := ExpandConstant(dotNetV4PackFile);
      if(FileOrDirExists(Path)) then
      begin
        Exec(Path, ‘/qb‘, ‘‘, SW_SHOW, ewWaitUntilTerminated, ResultCode);
        if RegKeyExists(HKLM, dotNetV4RegPath) then
        begin
           Result := true;
        end
        else
        begin
           MsgBox(‘未能成功安装.Net Framework4.0运行环境，系统将无法运行，本安装程序即将退出！‘,mbInformation,MB_OK);
        end
      end  
      else
      begin
          MsgBox(‘没有安装.Net Framework4.0运行环境，系统将无法运行，本安装程序即将退出！‘,mbInformation,MB_OK);
      end
  end;
end;

procedure DeinitializeSetup();
begin
    // Hide Window before unloading skin so user does not get
    // a glimse of an unskinned window before it is closed.
    ShowWindow(StrToInt(ExpandConstant(‘{wizardhwnd}‘)), 0);
    UnloadSkin();
end;


[Icons]
;{group}开始菜单文件夹路径，由用户在安装程序的选择开始菜单文件夹向导页中选定
Name: "{group}\{#MyAppName1}"; Filename: "{app}\{#MyAppExeName1}";Components:communication
;{group}开始菜单文件夹路径，由用户在安装程序的选择开始菜单文件夹向导页中选定
Name: "{group}\{#MyAppName2}"; Filename: "{app}\{#MyAppExeName2}";Components:client
;{commondesktop}&{userdesktop}桌面文件夹路径
Name: "{commondesktop}\{#MyAppName1}"; Filename: "{app}\{#MyAppExeName1}"; Tasks: desktopicon;Components:communication
;{commondesktop}&{userdesktop}桌面文件夹路径
Name: "{commondesktop}\{#MyAppName2}"; Filename: "{app}\{#MyAppExeName2}"; Tasks: desktopicon;Components:client
;{uninstallexe}由安装程序提取的卸载程序的完整路径名
Name:"{group}\卸载{#MyAppName1}" ;Filename:"{uninstallexe}";IconFilename:"{app}\uninstall.ico";Components:communication
;{uninstallexe}由安装程序提取的卸载程序的完整路径名
Name:"{group}\卸载{#MyAppName2}" ;Filename:"{uninstallexe}";IconFilename:"{app}\uninstall.ico";Components:client

;可选。用来定义一些想用安装在用户系统中创建、修改或删除的注册表键/值。
;按默认，用安装程序创建的注册表键和值在卸载时不删除。如果想让卸载程序删除键或值，必须包含
;uninsdelete* 标记中的一个
[Registry]
Root:HKLM;Subkey:"Software\xxx";Flags:uninsdeletekeyifempty
Root:HKLM;Subkey:"Software\xxx\communication";Flags:uninsdeletekey;Components:communication
Root:HKLM;Subkey:"Software\xxx\communication";ValueType:string;ValueName:"InstallPath";ValueData:"{app}";Components:communication
Root:HKLM;Subkey:"Software\xxx\client";Flags:uninsdeletekey;Components:client
Root:HKLM;Subkey:"Software\xxx\client";ValueType:string;ValueName:"InstallPath";ValueData:"{app}";Components:client

[UninstallDelete]
Type:filesandordirs;Name:"{app}\Log"
Type:filesandordirs;Name:"{app}\ErrorTrace.xml"
Type:filesandordirs;Name:"{app}\*.*"

;可选。指定程序完成安装后，在安装程序显示最终对话框之前要执行的程序数
[Run]
Filename: "{app}\{#MyAppExeName1}"; Description: "{cm:LaunchProgram,{#StringChange(MyAppName1, ‘&‘, ‘&&‘)}}"; Flags: nowait postinstall skipifsilent;Components:communication
                                                                                                                                                                     
Filename: "{app}\{#MyAppExeName2}"; Description: "{cm:LaunchProgram,{#StringChange(MyAppName2, ‘&‘, ‘&&‘)}}"; Flags: nowait postinstall skipifsilent;Components:client