1. 哪个语句慢？
2. 不同的查询计划是怎样的？
3. SQL Server嗅探了哪些参数？
4. 表和索引的定义是怎样的？
5. 统计信息的分布情况如何？实时更新吗？

SET ARITHABORT ON
go
EXEC that_very_sp 4711, 123, 1
go
SET ARITHABORT OFF
go
EXEC that_very_sp 4711, 123, 1

DECLARE @dbname NVARCHAR(256),
	@procname NVARCHAR(256)

SELECT @dbname = ‘Northwind‘,
	@procname = ‘dbo.List_orders_11‘;

WITH basedata
AS (
	SELECT qs.statement_start_offset / 2 AS stmt_start,
		qs.statement_end_offset / 2 AS stmt_end,
		est.encrypted AS isencrypted,
		est.TEXT AS sqltext,
		epa.value AS set_options,
		qp.query_plan,
		charindex(‘<ParameterList>‘, qp.query_plan) + len(‘<ParameterList>‘) AS paramstart,
		charindex(‘</ParameterList>‘, qp.query_plan) AS paramend
	FROM sys.dm_exec_query_stats qs
	CROSS APPLY sys.dm_exec_sql_text(qs.sql_handle) est
	CROSS APPLY sys.dm_exec_text_query_plan(qs.plan_handle, qs.statement_start_offset, qs.statement_end_offset) qp
	CROSS APPLY sys.dm_exec_plan_attributes(qs.plan_handle) epa
	WHERE est.objectid = object_id(@procname)
		AND est.dbid = db_id(@dbname)
		AND epa.attribute = ‘set_options‘
	),
next_level
AS (
	SELECT stmt_start,
		set_options,
		query_plan,
		CASE 
			WHEN isencrypted = 1
				THEN ‘-- ENCRYPTED‘
			WHEN stmt_start >= 0
				THEN substring(sqltext, stmt_start + 1, CASE stmt_end
							WHEN 0
								THEN datalength(sqltext)
							ELSE stmt_end - stmt_start + 1
							END)
			END AS Statement,
		CASE 
			WHEN paramend > paramstart
				THEN CAST(substring(query_plan, paramstart, paramend - paramstart) AS XML)
			END AS params
	FROM basedata
	)
SELECT set_options AS [SET],
	n.stmt_start AS Pos,
	n.Statement,
	CR.c.value(‘@Column‘, ‘nvarchar(128)‘) AS Parameter,
	CR.c.value(‘@ParameterCompiledValue‘, ‘nvarchar(128)‘) AS [Sniffed Value],
	CAST(query_plan AS XML) AS [Query plan]
FROM next_level n
CROSS APPLY n.params.nodes(‘ColumnReference‘) AS CR(c)
ORDER BY n.set_options,
	n.stmt_start,
	Parameter

USE Northwind
GO

CREATE PROCEDURE List_orders_11 @fromdate DATETIME,
	@custid NCHAR(5)
AS
SELECT @fromdate = dateadd(YEAR, 2, @fromdate)

SELECT *
FROM Orders
WHERE OrderDate > @fromdate
	AND CustomerID = @custid

IF @custid = ‘ALFKI‘
	CREATE INDEX test ON Orders (ShipVia)

SELECT *
FROM Orders
WHERE CustomerID = @custid
	AND OrderDate > @fromdate

IF @custid = ‘ALFKI‘
	DROP INDEX test
		ON Orders
GO

SET ARITHABORT ON

EXEC List_orders_11 ‘19980101‘,
	‘ALFKI‘
GO

SET ARITHABORT OFF

EXEC List_orders_11 ‘19970101‘,
	‘BERGS‘

• SET——表示查询计划中set_options属性。正如前面提到的，这是一个位掩码。上图中可以看到两个值：251 为默认设置，4347为默认设置+ARITHABORT ON。如果看到其他值，可以用作者编写的一个函数反编译：setoptions 。
• Pos——表示该语句在存储过程的起始位置，从存储过程创建语句起算，包括任何CREATE PROCEDURE之前的注释。虽然大部分情况下作用不大，但是可以看到语句在存储过程中的出现顺序。
• Statement——SQL语句，但是注意对于每个参数，都会重复一次。
• Parameter——参数名，仅列出语句中出现的参数。也就是说，如果该查询语句没有使用到的参数，是不会出现在这里的。
• Sniffed Value——在编译时的参数值，也就是在嗅探优化并产生查询计划的参数值。因为这是从计划缓存中获取的信息，所以这里的值并不是实际参数值，从上图中可以看到，对于不同的语句可能会出现不同的参数值。
• Query Plan——对应的预估执行计划。

DECLARE @tbl NVARCHAR(265)

SELECT @tbl = ‘Orders‘

SELECT o.NAME,
	i.index_id,
	i.NAME,
	i.type_desc,
	substring(ikey.cols, 3, len(ikey.cols)) AS key_cols,
	substring(inc.cols, 3, len(inc.cols)) AS included_cols,
	stats_date(o.object_id, i.index_id) AS stats_date,
	i.filter_definition
FROM sys.objects o
JOIN sys.indexes i
	ON i.object_id = o.object_id
CROSS APPLY (
	SELECT ‘, ‘ + c.NAME + CASE ic.is_descending_key
			WHEN 1
				THEN ‘ DESC‘
			ELSE ‘‘
			END
	FROM sys.index_columns ic
	JOIN sys.columns c
		ON ic.object_id = c.object_id
			AND ic.column_id = c.column_id
	WHERE ic.object_id = i.object_id
		AND ic.index_id = i.index_id
		AND ic.is_included_column = 0
	ORDER BY ic.key_ordinal
	FOR XML PATH(‘‘)
	) AS ikey(cols)
OUTER APPLY (
	SELECT ‘, ‘ + c.NAME
	FROM sys.index_columns ic
	JOIN sys.columns c
		ON ic.object_id = c.object_id
			AND ic.column_id = c.column_id
	WHERE ic.object_id = i.object_id
		AND ic.index_id = i.index_id
		AND ic.is_included_column = 1
	ORDER BY ic.index_column_id
	FOR XML PATH(‘‘)
	) AS inc(cols)
WHERE o.NAME = @tbl
	AND i.type IN (
		1,
		2
		)
ORDER BY o.NAME,
	i.index_id

DECLARE @tbl NVARCHAR(265)

SELECT @tbl = ‘Orders‘

SELECT o.NAME,
	s.stats_id,
	s.NAME,
	s.auto_created,
	s.user_created,
	substring(scols.cols, 3, len(scols.cols)) AS stat_cols,
	stats_date(o.object_id, s.stats_id) AS stats_date,
	s.filter_definition
FROM sys.objects o
JOIN sys.stats s
	ON s.object_id = o.object_id
CROSS APPLY (
	SELECT ‘, ‘ + c.NAME
	FROM sys.stats_columns sc
	JOIN sys.columns c
		ON sc.object_id = c.object_id
			AND sc.column_id = c.column_id
	WHERE sc.object_id = s.object_id
		AND sc.stats_id = s.stats_id
	ORDER BY sc.stats_column_id
	FOR XML PATH(‘‘)
	) AS scols(cols)
WHERE o.NAME = @tbl
ORDER BY o.NAME,
	s.stats_id

UPDATE STATISTICS 表名 WITH FULLSCAN, INDEX

UPDATE STATISTICS tbl indexname WITH FULLSCAN

DBCC SHOW_STATISTICS (Orders, OrderDate)