codevs1028花店橱窗布置（费用流）

var a,c:array[0..210,0..210]of longint;//a是原图，c是花费的图
  fa,d:array[0..210]of longint;//fa[i]是在到i的最短路径上i的前一个点（前驱结点），d[i]是到i的最短路径的距离
  b:array[0..210]of boolean;//记录是否在队列中
  q:array[0..40010]of longint;//队列
  n,m,i,j,k,p,t,h,sum:longint;
procedure spfa(s:longint);//spfa模板
var i,h,t:longint;
begin
  for i:=0 to n do begin
    d[i]:=-1<<25; b[i]:=true;//初始化
  end;
  h:=1; t:=1; q[1]:=s; d[s]:=0; b[s]:=false; fa[s]:=-1;//初始化2
  repeat
    for i:=0 to n do
      if(a[q[h],i]>0)and(d[q[h]]+c[q[h],i]>d[i])then begin//判断是否有边，是否更优
        d[i]:=d[q[h]]+c[q[h],i]; fa[i]:=q[h];//更新距离
        if b[i] then begin
          inc(t); q[t]:=i; b[i]:=false;//入队
        end;
      end;
    b[q[h]]:=true; inc(h);//出队
  until h>t;
end;
function flow(s,t:longint):longint;
var p,min:longint;
begin
  spfa(s);
  if d[t]=-1<<25 then exit(0);//判断是否有增广路
  p:=t; min:=1<<25;
  while fa[p]>=0 do begin
    if min>a[fa[p],p] then min:=a[fa[p],p];//从汇点访问到源点，计算流量
    p:=fa[p];
  end;
  p:=t;                               
  while fa[p]>=0 do begin
    c[p,fa[p]]:=-c[fa[p],p];//建反向边1
    a[fa[p],p]:=a[fa[p],p]-min; a[p,fa[p]]:=a[p,fa[p]]+min;//建反向边2
    p:=fa[p];
  end;
  sum:=sum+d[t];//加上这次增广的花费，更新答案
  exit(min);
end;
begin
  read(n,m);
  for i:=1 to n do begin
    a[0,i]:=1; c[0,i]:=0;//建图1
  end;
  for i:=1 to m do begin
    a[i+n,n+m+1]:=1; c[i+n,n+m+1]:=0;//建图2
  end;
  for i:=1 to n do
    for j:=1 to m do begin
      read(k); a[i,n+j]:=1; c[i,n+j]:=k;//建图3
    end;
  n:=n+m+1; sum:=0; k:=1;
  while k>0 do k:=flow(0,n);//一行费用流
  writeln(sum);//输出最大美学值
end.