AutoIt上路03-添加工具栏

标签：自定义   基本用法   func   nbsp   constant   图像   file   menuitem   register   

AutoIt上路03-添加工具栏

　　按照我的设计，程序中会有多个界面，用以实现不同的管理主题。其中程序运行后有个默认界面，然后根据需要再打开更多界面；如果有多个界面打开，则显示在标签卡中，通过标签切换显示。

本文实现标签卡功能，描述其基本用法。
　　1。在窗体内创建标签卡控件，GUICtrlCreateTab
　　2。为标签卡添加点击事件处理，GUICtrlSetOnEvent
　　3。为标签卡添加标签，GUICtrlCreateTabItem
　　4。根据需要为标签头设置图片
　　5。结束选项标签页的定义，GUICtrlCreateTabItem(“”)

AutoIt内置创建标签卡的函数，提供了基本功能，用户定义函数目录\GUI参考\标签选项卡管理 中提供了更为丰富的函数，两者可以结合使用；当然仅使用自定义函数也可以做出高级功能的应用。

1. #include <GUIConstantsEx.au3>
2. #include <GuiTab.au3> ; 用户自定义函数
3. #include <GuiToolbar.au3>
4. #include <GuiImageList.au3>
5. #include <WinAPI.au3>
6. #include <WindowsConstants.au3>
7.  
8. Opt("GUIOnEventMode", 1)
9.  
10. Global $itemInToolbar
11.  
12. $guiWelcome = GUICreate("威格灵", 400, 200)
13. GUISetOnEvent($GUI_EVENT_CLOSE, "Func_GUI_EVENT_CLOSE")
15. $menuFile = GUICtrlCreateMenu ( "文件 &F")
16. $itemOpenInMenuFile = GUICtrlCreateMenuItem("打开", $menuFile)
17. GUICtrlCreateMenuItem("", $menuFile)
18. $itemExitInMenuFile = GUICtrlCreateMenuItem("退出", $menuFile)
19. GUICtrlSetOnEvent($itemExitInMenuFile, "Func_GUI_EVENT_CLOSE")
21. $toolbar = _GUICtrlToolbar_Create($guiWelcome)
22. _GUICtrlToolbar_AddBitmap($toolbar, 1, -1, $IDB_STD_SMALL_COLOR)
23. Local Enum $id_New = 1000, $id_Open, $id_Save, $id_Find, $id_Help
24. _GUICtrlToolbar_AddButton($toolbar, $id_New, $STD_FILENEW)
25. _GUICtrlToolbar_AddButton($toolbar, $id_Open, $STD_FILEOPEN)
26. _GUICtrlToolbar_AddButton($toolbar, $id_Save, $STD_FILESAVE)
27. _GUICtrlToolbar_AddButtonSep($toolbar)
28. _GUICtrlToolbar_AddButton($toolbar, $id_Find, $STD_FIND)
29. _GUICtrlToolbar_AddButtonSep($toolbar)
30. _GUICtrlToolbar_AddButton($toolbar, $id_Help, $STD_HELP)
31.  
32. ; 1。创建标签卡控件（x-距离窗体左边，y-距离窗体顶边，w，h），注意上面的工具条也占用高度，同时菜单栏底边设为0
33. $tabWelcome = GUICtrlCreateTab ( 1, 28, 398, 130) ; 标签头的高度约 22
34. ; 2。为标签卡添加点击事件处理
35. GUICtrlSetOnEvent($tabWelcome, "Func_TabWelcome")
37. ; 3。添加标签（标题）。起始索引为0
38. $item0InTabWelcome = GUICtrlCreateTabItem("工程师记录")
39. ; 4。在标签内添加控件。标签内的控件位置都是相对于窗体的，而不是此标签卡
40. GUICtrlCreateLabel("文本 0", 3, 52, 50, 20)
42. ; 5。添加新的标签
43. $item1InTabWelcome = GUICtrlCreateTabItem("产品展示")
44. GUICtrlCreateCombo("", 3, 52, 160, 120) ; 下拉框
45. GUICtrlSetData(-1, "数字地理教室|数字数学教师|数字化学教室|互动物理教室|崔维友作品|vigiles", "崔维友作品") ; 添加项目，默认选中 "崔维友作品"
46.  
47. $item2InTabWelcome = GUICtrlCreateTabItem("学校信息管理")
48. GUICtrlSetState(-1, $GUI_SHOW) ; 将首先显示
49. GUICtrlCreateButton("确定", 3, 52, 50, 22)
51. ;----------------------------------------- 可选 start ----------------------------------------
52. ; 创建图像列表(ImageList)控件
53. $imgList = _GUIImageList_Create()
55. ; 添加一或多个图像到图像列表（图像列表控件，调用WinAPI.au3创建单色位图）
56. _GUIImageList_Add($imgList, _WinAPI_CreateSolidBitmap($guiWelcome, 0xFF0000, 16, 16))
57. _GUIImageList_Add($imgList, _WinAPI_CreateSolidBitmap($guiWelcome, 0x00FF00, 16, 16))
58. _GUIImageList_Add($imgList, _WinAPI_CreateSolidBitmap($guiWelcome, 0x0000FF, 16, 16))
60. ;设置(标签选项卡)控件关联的图像列表（标签卡，图像列表）
61. _GUICtrlTab_SetImageList($tabWelcome, $imgList)
63. ; 设置(标签选项卡)的标签图像（标签卡，标签索引-始于0，图像索引-始于0）
64. _GUICtrlTab_SetItemImage($tabWelcome, 0, 0)
65. _GUICtrlTab_SetItemImage($tabWelcome, 1, 1)
66. _GUICtrlTab_SetItemImage($tabWelcome, 2, 2)
68. ;----------------------------------------- 可选 end ------------------------------------------
70. ; 6。结束选项标签页的定义
71. GUICtrlCreateTabItem("")
72.  
73. ; 后于标签卡创建，会在其顶层。注意x、y，否则可能遮挡标签卡
74. GUICtrlCreateLabel("文本 3", 1, 160, 50, 20)
75.  
76. GUISetState(@SW_SHOW, $guiWelcome)
77.  
78. GUIRegisterMsg($WM_NOTIFY, "_WM_NOTIFY")
79.  
80. ;-------------------------------- 分割线 -----------------------------
81. While 1
82. Sleep(200)
83. WEnd
84.  
85. Func Func_GUI_EVENT_CLOSE ()
86. Exit
87. EndFunc
88.  
89. ; 响应标签卡点击事件
90. Func Func_TabWelcome ()
91. ; 获得标签索引。@GUI_CtrlId宏命令，获取刚刚点击的控件ID
92. $ctrlId = GUICtrlRead (@GUI_CtrlId)
93. ; 获得标签标题文本（控件，索引）
94. $itemText = _GUICtrlTab_GetItemText(@GUI_CtrlId, $ctrlId)
96. MsgBox(0, "提示", "你点击的标签卡：" & $ctrlId & " - " & $itemText )
97. EndFunc
98.  
99. Func _WM_NOTIFY($hWndGUI, $MsgID, $wParam, $lParam)
100. ; 未改动，内容略
101. EndFunc

AutoIt上路03-添加工具栏

标签：自定义   基本用法   func   nbsp   constant   图像   file   menuitem   register   

原文地址：http://www.cnblogs.com/itviplearning/p/7047080.html