考勤问题思路和解决

标签：考勤系统   sql   

最近在做一个考勤系统，考勤主要关注的是缺勤、迟到和早退，目前的打卡控制器可以记录用户名和打卡时间，用户可能一天打卡多次，也可能一天只打了一次卡，这些情况都需要考虑。打卡信息都存储在考勤表中，从中要挖掘出一个月内的缺勤人员，迟到人员和早退人员，并且能显示缺勤、迟到和早退的时间。

考勤表

CREATE TABLE [dbo].[kaoqin](
	[user_name] [varchar](50) NULL,
	[card_time] [datetime] NULL
) ON [PRIMARY]

GO

INSERT INTO [master].[dbo].[kaoqin]
select '张三', '2014-08-03 09:36:00'
union all
select '张三', '2014-08-03 18:10:00'
union all
select '张三', '2014-08-04 08:32:00'
union all
select '张三', '2014-08-04 15:15:00'
union all
select '张三', '2014-08-05 09:32:00'
union all
select '张三', '2014-08-05 15:15:00'
union all
select '张三', '2014-08-01 08:36:00'
union all
select '张三', '2014-08-01 18:10:00'
union all
select '张三', '2014-08-02 08:32:00'
union all
select '张三', '2014-08-02 18:15:00'
union all
select '张三', '2014-08-25 08:00:00'
union all
select '张三', '2014-08-24 19:00:00'
union all
select '张三', '2014-08-27 08:00:00'
union all
select '张三', '2014-08-27 17:00:00'
union all
select '张三', '2014-08-26 10:00:00'
union all
select '张三', '2014-08-26 18:30:00'
union all
select '张三', '2014-08-26 8:00:00'
union all
select '张三', '2014-08-27 18:56:00'
          
GO

declare @time_start datetime
declare	@time_end datetime 

set @time_start = '2014-08-01 00:00:00'
set @time_end = DATEADD(M,1,@time_start)

-- 一个月的工作日
IF object_id('tempdb..#tempDate') is not null
BEGIN
	drop table #tempDate
END
CREATE table #tempDate
(	
	stat_day varchar(10)
)

IF object_id('tempdb..#tempUserDate') is not null
BEGIN
	drop table #tempUserDate
END
CREATE table #tempUserDate
(	
	
	stat_day varchar(10),
	[user_name] varchar(40)
)
CREATE clustered index tempUserDate_Index1 on #tempUserDate ([user_name],stat_day)

declare @time_temp datetime
set @time_temp = @time_start
while @time_temp < @time_end
begin
   if datepart(weekday,@time_temp)>1 and datepart(weekday,@time_temp)<7
   begin
	   insert into #tempDate (stat_day) values (CONVERT(varchar(10),@time_temp,121))
   end
   set @time_temp= dateadd(d,1,@time_temp)
end

insert into #tempUserDate
select * from #tempDate  cross join
(select distinct [user_name] from [kaoqin]) t

select [user_name],CONVERT(varchar(10),card_time,121) as stat_day,
    MIN(card_time) as on_time,MAX(card_time) as off_time from [kaoqin]
    group by [user_name],CONVERT(varchar(10),card_time,121)

--缺勤
select * from #tempUserDate a
left join
(
    select [user_name],CONVERT(varchar(10),card_time,121) as stat_day,
    MIN(card_time) as on_time,MAX(card_time) as off_time from [kaoqin]
    group by [user_name],CONVERT(varchar(10),card_time,121)
) b on a.[user_name]=b.[user_name] and a.stat_day=b.stat_day
where [b].[user_name] is null

--迟到
select * from #tempUserDate a
left join
(
    select [user_name],CONVERT(varchar(10),card_time,121) as stat_day,
    MIN(card_time) as on_time,MAX(card_time) as off_time from [kaoqin]
    group by [user_name],CONVERT(varchar(10),card_time,121)
) b on a.[user_name]=b.[user_name] and a.stat_day=b.stat_day
where CONVERT(varchar(100), [b].[on_time], 8)>'09:00:00'

--早退
select * from #tempUserDate a
left join
(
    select [user_name],CONVERT(varchar(10),card_time,121) as stat_day,
    MIN(card_time) as on_time,MAX(card_time) as off_time from [kaoqin]
    group by [user_name],CONVERT(varchar(10),card_time,121)
) b on a.[user_name]=b.[user_name] and a.stat_day=b.stat_day
where CONVERT(varchar(100), [b].[off_time], 8)<'18:00:00'

如果某个人他今天既迟到又早退在最终的结果中都会体现，可以从2014-08-05这条数据看出。当然，这个考勤系统还不完善，例如没有将节日考虑进来，初步的考虑是采用Job定期存储每年的节日，如果员工请假，也需要纳入到系统的考虑中。

考勤问题思路和解决

标签：考勤系统   sql   

原文地址：http://blog.csdn.net/dotnetstudio/article/details/39006979