8254

标签：pc机   偏移地址   ret   quit   nbsp   segment   入口   中断   实验   

;T8254-1.asm

;查看端口资源分配情况，记录实验系统I/O端口始地址

INTR_IVADD     EQU   003CH        ;INTR对应的中断矢量地址

IOY0           EQU   0C000H        ;片选IOY0对应的端口始地址
MY8254_COUNT0  EQU   IOY0+00H*2   ;8254计数器0端口地址
MY8254_COUNT1  EQU   IOY0+01H*2   ;8254计数器1端口地址
MY8254_COUNT2  EQU   IOY0+02H*2   ;8254计数器2端口地址
MY8254_MODE    EQU   IOY0+03H*2   ;8254控制寄存器端口地址
                             
STACK1 SEGMENT STACK
        DW 256 DUP(?)
STACK1 ENDS

DATA SEGMENT
CS_BAK   DW  ?                    ;保存INTR原中断处理程序入口段地址的变量
IP_BAK   DW  ?                    ;保存INTR原中断处理程序入口偏移地址的变量
IM_BAK   DB  ?                    ;保存INTR原中断屏蔽字的变量
STR1     DB  ‘COUNT: $‘           ;显示的字符串
DATA ENDS

CODE SEGMENT
        ASSUME CS:CODE,DS:DATA

START: MOV AX,DATA
       MOV DS,AX
       CLI

       MOV AX,0000H               ;替换INTR的中断矢量
       MOV ES,AX
       MOV DI,INTR_IVADD         
       MOV AX,ES:[DI]
       MOV IP_BAK,AX              ;保存INTR原中断处理程序入口偏移地址
       MOV AX,OFFSET MYISR
       MOV ES:[DI],AX             ;设置当前中断处理程序入口偏移地址

       ADD DI,2
       MOV AX,ES:[DI]
       MOV CS_BAK,AX              ;保存INTR原中断处理程序入口段地址
       MOV AX,SEG MYISR
       MOV ES:[DI],AX             ;设置当前中断处理程序入口段地址

       IN  AL,21H
       MOV IM_BAK,AL              ;保存INTR原中断屏蔽字
       AND AL,7FH
       OUT 21H,AL

       STI
       MOV DX,OFFSET STR1         ;显示字符串
       MOV AH,9
       INT 21H

       MOV DX,MY8254_MODE         ;初始化8254工作方式
       MOV AL,10H                 ;计数器0，方式0 
       OUT DX,AL            

       MOV DX,MY8254_COUNT0       ;装入计数初值
       MOV AL,4
       OUT DX,AL

WAIT1: MOV AH,1                   ;判断是否有按键按下
       INT 16H
       JZ  WAIT1                  ;无按键则跳回继续等待，有则退出

QUIT:  CLI

       MOV AX,0000H               ;恢复INTR原中断矢量
       MOV ES,AX
       MOV DI,INTR_IVADD 
       MOV AX,IP_BAK              ;恢复INTR原中断处理程序入口偏移地址
       MOV ES:[DI],AX
       ADD DI,2
       MOV AX,CS_BAK              ;恢复INTR原中断处理程序入口段地址
       MOV ES:[DI],AX

       MOV AL,IM_BAK              ;恢复INTR原中断屏蔽寄存器的屏蔽字
       OUT 21H,AL
       STI

       MOV AX,4C00H               ;返回到DOS
       INT 21H

MYISR PROC NEAR                   ;中断处理程序MYISR
       PUSH AX
       MOV AL,35H
       MOV AH,0EH
       INT 10H
       MOV AL,20H
       INT 10H

       MOV DX,MY8254_COUNT0       ;重装计数初值
       MOV AL,4
       OUT DX,AL

OVER:  MOV AL,20H                 ;向PC机内部8259发送中断结束命令
       OUT 20H,AL
       POP AX
       IRET
      
MYISR ENDP
      
CODE ENDS
     END START

;T8254-2.asm
;8254定时应用实验  输出1Hz

;查看端口资源分配情况，记录实验系统I/O端口始地址

;****************根据查看端口资源修改下列符号值*******************
IOY0           EQU   0C000H         ;片选IOY0对应的端口始地址
;*****************************************************************
MY8254_COUNT0  EQU   IOY0+00H*2   ;8254计数器0端口地址
MY8254_COUNT1  EQU   IOY0+01H*2   ;8254计数器1端口地址
MY8254_COUNT2  EQU   IOY0+02H*2   ;8254计数器2端口地址
MY8254_MODE    EQU   IOY0+03H*2   ;8254控制寄存器端口地址
                             
STACK1 SEGMENT STACK
        DW 256 DUP(?)
STACK1 ENDS

CODE SEGMENT
        ASSUME CS:CODE

START: MOV DX,MY8254_MODE         ;初始化8254工作方式
       MOV AL,76H                 ;计数器1，方式3
       OUT DX,AL
               
       MOV DX,MY8254_COUNT1       ;装入计数初值
       MOV AL,64H                 ;100分频
       OUT DX,AL
       MOV AL,00H
       OUT DX,AL

       MOV DX,MY8254_MODE         ;初始化8254工作方式
       MOV AL,36H                 ;计数器0，方式3
       OUT DX,AL
               
       MOV DX,MY8254_COUNT0       ;装入计数初值
       MOV AL,00H                 ;18432分频
       OUT DX,AL
       MOV AL,48H
       OUT DX,AL
      
QUIT:  MOV AX,4C00H               ;结束程序退出
       INT 21H
      
CODE ENDS
     END START

8254

标签：pc机   偏移地址   ret   quit   nbsp   segment   入口   中断   实验   

原文地址：http://www.cnblogs.com/s1104119631/p/7816855.html