1 /* 指定输出的可执行文件 elf 格式，32位，小端  */
  2 OUTPUT_FORMAT("elf32-littlearm", "elf32-littlearm", "elf32-littlearm")
  3 /* 指定输出可执行文件的平台为 arm */
  4 OUTPUT_ARCH(arm)
  5 /* 指定输出可执行文件的起始代码段为_start */
  6 ENTRY(_start)
  7 /* 指定可执行文件的全局入口点，通常这个地址都放在ROM(flash)0x0位置。
  8  * 必须使编译器知道这个地址 */
  9 SECTIONS
 10 {
 11     /* 从0x0位置开始  */
 12  . = 0x00000000;
 13     /* 代码以4字节对齐 */
 14  . = ALIGN(4);
 15     /* 代码段 */
 16  .text :
 17  {
 18         /* u-boot将自己copy到RAM，此为需要copy的程序的start */
 19   *(.__image_copy_start)
 20         /* ./arch/arm/lib/vectors.S，异常向量表 */
 21   *(.vectors)
 22         /* ./arch/arm/cpu/arm920t/start.S */
 23   arch/arm/cpu/arm920t/start.o (.text*)
 24         /* 其他的代码段放在这里，即 start.S/vector.S 之后 */
 25   *(.text*)
 26  }
 27     /* 代码段结束后，有可能4bytes不对齐了，此时做好4bytes对齐，以开始后面的.rodata段 */
 28  . = ALIGN(4);
 29     /* 在代码段之后，存放read only数据段 */
 30  .rodata : { *(SORT_BY_ALIGNMENT(SORT_BY_NAME(.rodata*))) }
 31     /* 4bytes对齐，以开始接下来的.data段 */
 32  . = ALIGN(4);
 33     /* 可读写数据段 */
 34  .data : {
 35   *(.data*)
 36  }
 37     /* 4字节对齐 */
 38  . = ALIGN(4);
 39     /* 当前地址为4字节对齐后的地址 */
 40  . = .;
 41     /* 4字节对齐 */
 42  . = ALIGN(4);
 43     /* .data段结束后，紧接着存放u-boot自有的一些function，例如u-boot command等 */
 44  .u_boot_list : {
 45   KEEP(*(SORT(.u_boot_list*)));
 46  }
 47  . = ALIGN(4);
 48     /* UEFI支持，  */
 49  .__efi_runtime_start : {
 50   *(.__efi_runtime_start)
 51  }
 52     /*  */
 53  .efi_runtime : {
 54   *(efi_runtime_text)
 55   *(efi_runtime_data)
 56  }
 57     /* */
 58  .__efi_runtime_stop : {
 59   *(.__efi_runtime_stop)
 60  }
 61     /*  */
 62  .efi_runtime_rel_start :
 63  {
 64   *(.__efi_runtime_rel_start)
 65  }
 66     /* */
 67  .efi_runtime_rel : {
 68   *(.relefi_runtime_text)
 69   *(.relefi_runtime_data)
 70  }
 71     /* UEFI结束  */
 72  .efi_runtime_rel_stop :
 73  {
 74   *(.__efi_runtime_rel_stop)
 75  }
 76     /* 4字节对齐  */
 77  . = ALIGN(4);
 78     /* 至此，u-boot需要自拷贝的内容结束，总结一下，包括代码段，数据段，以及u_boot_list */
 79  .image_copy_end :
 80  {
 81   *(.__image_copy_end)
 82  }
 83     /* 在老的uboot中，如果我们想要uboot启动后把自己拷贝到内存中的某个地方，只要把要拷贝的地址写给TEXT_BASE即可，
 84      * 然后boot启动后就会把自己拷贝到TEXT_BASE内的地址处运行，在拷贝之前的代码都是相对的，不能出现绝对的跳转，否则会跑飞。
 85      * 在新版的uboot里，TEXT_BASE的含义改变了。它表示用户要把这段代码加载到哪里，通常是通过串口等工具。
 86      * 然后搬移的时候由uboot自己计算一个地址来进行搬移。新版的uboot采用了动态链接技术，在lds文件中有__rel_dyn_start和__rel_dyn_end，
 87      * 这两个符号之间的区域存放着动态链接符号，只要给这里面的符号加上一定的偏移，拷贝到内存中代码的后面相应的位置处，
 88      * 就可以在绝对跳转中找到正确的函数。 */
 89  .rel_dyn_start :
 90  {
 91   *(.__rel_dyn_start)
 92  }
 93     /* 动态链接符存放在的段 */
 94  .rel.dyn : {
 95   *(.rel*)
 96  }
 97     /* 动态链接符段结束 */
 98  .rel_dyn_end :
 99  {
100   *(.__rel_dyn_end)
101  }
102  .end :
103  {
104   *(.__end)
105  }
106     /* bin文件结束 */
107  _image_binary_end = .;
108  . = ALIGN(4096);
109  .mmutable : {
110   *(.mmutable)
111  }
112  
113     /* .bss节包含了程序中所有未初始化的全局变量 */
114  .bss_start __rel_dyn_start (OVERLAY) : {
115   KEEP(*(.__bss_start));
116   __bss_base = .;
117  }
118  .bss __bss_base (OVERLAY) : {
119   *(.bss*)
120    . = ALIGN(4);
121    __bss_limit = .;
122  }
123     /* bss段结束 */
124  .bss_end __bss_limit (OVERLAY) : {
125   KEEP(*(.__bss_end));
126  }
127 
128  .dynsym _image_binary_end : { *(.dynsym) }
129  .dynbss : { *(.dynbss) }
130  .dynstr : { *(.dynstr*) }
131  .dynamic : { *(.dynamic*) }
132  .plt : { *(.plt*) }
133  .interp : { *(.interp*) }
134  .gnu.hash : { *(.gnu.hash) }
135  .gnu : { *(.gnu*) }
136  .ARM.exidx : { *(.ARM.exidx*) }
137  .gnu.linkonce.armexidx : { *(.gnu.linkonce.armexidx.*) }
138 }