标签：down   策略   思路分析   期望   情况   margin   exit   思路   类型   

早上的考试一道都做不出，被教做人，心态爆炸ing。。。。。。

题目描述：

你正在玩你最喜欢的电子游戏，并且刚刚进入一个奖励关。在这个奖励关里，系统将依次随机抛出k次宝物，每次你都可以选择吃或者不吃（必须在抛出下一个宝物之前做出选择，且现在决定不吃的宝物以后也不能再吃）。

宝物一共有n种，系统每次抛出这n种宝物的概率都相同且相互独立。也就是说，即使前k-1 次系统都抛出宝物1（这种情况是有可能出现的，尽管概率非常小），第k次抛出各个宝物的概率依然均为1/n。

获取第 i 种宝物将得到Pi分，但并不是每种宝物都是可以随意获取的。第i种宝物有一个前提宝物集合Si。只有当Si中所有宝物都至少吃过一次，才能吃第i 种宝物（如果系统抛出了一个目前不能吃的宝物，相当于白白的损失了一次机会）。注意，Pi 可以是负数，但如果它是很多高分宝物的前提，损失短期利益而吃掉这个负分宝物将获得更大的长期利益。

假设你采取最优策略，平均情况你一共能在奖励关得到多少分值？

1 <= k <= 100, 1 <= n <= 15，分值为[-106,106]内的整数。

思路分析：

n很小，很明显的状压DP，二进制状态sta表示n件宝物吃的状态，0表示还没吃，1表示吃过了。推出dp的状态，f[i][sta]表示目前处于第i轮，在前i轮吃到宝物的状态为sta，采用最优策略能够得到的最大期望价值。

转移时枚举j，表示第i个轮，掉下的是j号宝物。

但是会发现转移很难写，或者说根本写不了。为什么呢？下面就和大家来讨论一下。

写我为人人型——无法判断第i个宝物吃与不吃哪一个更优（因为推过去之后一个取的话是[i+1][sta|1<<(j-1)]，不取的话是[i+1][sta]，两者不一致）

写人人为我型——无法判断它是由哪一个状态转移过来的 （因为可能第i轮枚举到的j是唯一的一个j类型宝物，而也有可能是唯一的一个，所以很难分辨该从哪一种状态转移过来）

那么我们应该怎么做呢？——正着做怎么都不行，那就倒着来呗！

状态：f[i][sta]表示从第i轮到第k（总轮数），都取最优方案，而现在正处于第i-1回合，吃到宝物的状态为sta，能够得到的最大期望价值。

转移时枚举一个j表示在第i-1轮出现的宝物为j（下面的pre数组是由宝物j能够被选的前提物品01（二进制上第i位0/1表示第i件物品是/不是物品j的前提物品）状态压成的十进制数，w为价值）

条件：sta|pre[j]=pre[j]               转移：f[i][sta]=f[i][sta]+max(f[i+1,sta],f[i+1,sta|1<<(j-1)]+w[j])

条件：sta|pre[j]<>pre[j]             转移：f[i][sta]=f[i][sta]+f[i+1][sta]

其中f[i+1][sta|1<<(j-1)]表示第i-1轮吃宝物j，f[i+1][sta]表示第i-1轮不吃宝物j。

代码实现：

var
  f:array[0..101,0..50000]of double;
  pre,w:array[0..15]of longint;
  x,k,n,i,sta,j:longint;
function max(a,b:double):double;
begin
  if a>b then exit(a) else exit(b);
end;
begin
  read(k,n);
  for i:=1 to n do
  begin
    read(w[i],x);
    while x<>0 do
    begin
      pre[i]:=pre[i] or 1<<(x-1);
      read(x);
    end;
  end;
  for i:=k downto 1 do
    for sta:=0 to 1<<n-1 do
      for j:=1 to n do
        if sta and pre[j]=pre[j] then
          f[i,sta]:=f[i,sta]+max(f[i+1,sta]/n,(f[i+1,sta or 1<<(j-1)]+w[j])/n)
        else
          f[i,sta]:=f[i,sta]+f[i+1,sta]/n;
  writeln(f[1,0]:0:6);
end.

SCOI 2008 【奖励关】

标签：down   策略   思路分析   期望   情况   margin   exit   思路   类型   

原文地址：https://www.cnblogs.com/WR-Eternity/p/9857933.html