TPaintBox的前世今生

  TPaintBox = class(TGraphicControl)
  private
    FOnPaint: TNotifyEvent;
  protected
    procedure Paint; override;
  public
    constructor Create(AOwner: TComponent); override;
    property Canvas;
  end;

procedure TPaintBox.Paint;
begin
  Canvas.Font := Font;
  Canvas.Brush.Color := Color;
  if csDesigning in ComponentState then
    with Canvas do
    begin
      Pen.Style := psDash;
      Brush.Style := bsClear;
      Rectangle(0, 0, Width, Height);
    end;
  if Assigned(FOnPaint) then FOnPaint(Self);
end;

procedure TForm1.PaintBox1Paint(Sender: TObject);
var
  t: TRect;
begin
  t.Top:=0;
  t.Left:=0;
  t.Right:=100;
  t.Bottom:=100;
  PaintBox1.Canvas.FillRect(t); // 使用画刷的颜色填充区域的颜色
end;

// 第一步，Form1作为一个TControl，给它设置颜色时会调用：
procedure TControl.SetColor(Value: TColor);
begin
  if FColor <> Value then
  begin
    FColor := Value; // 简单设置类成员数据（不是类属性，后者会执行相关函数）
    FParentColor := False;
    Perform(CM_COLORCHANGED, 0, 0); // Form1颜色变化的一级入口
  end;
end;

// 第二步，连续执行三个CMColorChanged函数
procedure TCustomForm.CMColorChanged(var Message: TMessage);
begin
  inherited;
  if FCanvas <> nil then FCanvas.Brush.Color := Color; 
end;

procedure TWinControl.CMColorChanged(var Message: TMessage);
begin
  inherited; // 这里使自己(Form1)的显示效果失效，一旦新的绘制消息到达，就可以根据新内容重绘了
  FBrush.Color := FColor; // 然后设置类成员数据画刷的颜色
  NotifyControls(CM_PARENTCOLORCHANGED); // 通知所有子控件，Form1作为它们的父控件，自己的颜色已经变化了
end;

procedure TControl.CMColorChanged(var Message: TMessage);
begin
  Invalidate; // 虚函数，所以要看是谁调用的这个函数。在这个例子中，此时当前控件是Form1，所以会调用TWinControl.Invalidate;这个过程不再展开。
end;

// 第三步，把Form1自己的显示内容失效以后，还要继续通知所有子控件：
procedure TWinControl.NotifyControls(Msg: Word);
var
  Message: TMessage;
begin
  Message.Msg := Msg;
  Message.WParam := 0;
  Message.LParam := 0;
  Message.Result := 0;
  Broadcast(Message);
end;

procedure TWinControl.Broadcast(var Message);
var
  I: Integer;
begin
  for I := 0 to ControlCount - 1 do
  begin
    Controls[I].WindowProc(TMessage(Message)); // 挨个通知子控件，并调用它们的相关消息函数，如果有的话
    if TMessage(Message).Result <> 0 then Exit;
  end;
end;

// 第四步，结果PaintBox1作为子控件，还真收到了这个消息，并做出相应：
procedure TControl.CMParentColorChanged(var Message: TMessage);

  // Same as SetColor but doesn‘t set ParentBackground to False
  procedure SetParentColor(Value: TColor);
  begin
    if FColor <> Value then
    begin
      FColor := Value; // 把自己的颜色改成父控件的颜色
      FParentColor := False; // good 因为VCL库是非线程安全的，所以使了一个障眼法，临时不再接受新的颜色变化消息，但是一旦颜色变化完毕，马上就会改回来。
      Perform(CM_COLORCHANGED, 0, 0); // 发消息调用函数，使得自己的颜色变化当场生效
    end;
  end;

begin
  // 注意，在此消息处理过程中，没有改变消息的result值，因此Broadcast函数里的消息for循环得以不断执行
  if FParentColor then // 默认状态下就是如此
  begin
    if Message.wParam <> 0 then
      SetParentColor(TColor(Message.lParam)) else
      SetParentColor(FParent.FColor); // 调用子函数，把父控件的颜色设为自己的颜色，注意没有调用同名的类函数
    FParentColor := True; // 前面执行消息使颜色生效后，马上改回来
  end;
end;

// 第五步，前面最后一句是PaintBox1执行Perform(CM_COLORCHANGED, 0, 0);，相当于执行：
procedure TControl.CMColorChanged(var Message: TMessage);
begin
  Invalidate; // 会调用InvalidateControl函数使自己的显示内容失效，此处不再展开
end;

// 第六步，WM_PAINT消息来了以后，会通过PaintBox1.Paint函数间接执行程序员的代码

procedure TForm1.Button4Click(Sender: TObject);
begin
  PaintBox1.Canvas.Brush.Color:=clGreen; 
  PaintBox1.Invalidate; 
end;

procedure TForm1.Button4Click(Sender: TObject);
begin
  PaintBox1.Color:=clRed;
end;