@echo off&title 全盘搜索批量文件       小小沧海2012-3-6
setlocal EnableDelayedExpansion
rem 过滤器，要搜索的一组文件，每一个文件用/符号隔开，例：Rec*.rar/HD *.rar
set filter=
rem 子过滤器，用于在每个分区下搜索文件的临时过滤器
set subf=
set volume=

rem 模式1使用的是在每一分区内把要搜索的文件全部显示在一块，没有顺序
rem 模式2使用的是在每一分区内分别显示出搜索的每一个文件
:choose
echo ********全盘搜索批量文件*******
echo ┏━━━━━━━━━━━━━━┓
echo ┃模式[1]：适用于搜索少量文件 ┃
echo ┃模式[2]：适用于搜索大量文件 ┃
echo ┗━━━━━━━━━━━━━━┛
echo 请选择搜索模式：
set choose=n&set /p choose=
if not %choose%==1 (if not %choose%==2 cls&goto choose)

:filter
rem 如果过滤器没有被事先定义则提示由用户手动输入
if "%filter%"=="" (
  echo ┏━━━━━━━━━━━━━━━━━━━━━━━┓
  echo ┃每个文件之间用/符号分隔开，例如a*b.txt/d?e.*  ┃
  echo ┃支持通配符?和*，不要包含其他特殊符号          ┃
  echo ┗━━━━━━━━━━━━━━━━━━━━━━━┛
  echo 请输入要搜索的批量文件：
  set filter=n&set /p filter=
  if "!filter!"=="n" (set filter=& cls & goto :filter)
  set filter=!filter:"=!
)

rem 如果使用模式1则需要将过滤器修正为模式1支持的形式
rem 模式1使用dir命令自带的查找批量文件功能，形式为每个文件加双引号并用空格隔开,例"a*.*" "e?f.doc"
if %choose%==1 (
  set filter="!filter:"=!"
  set filter=!filter:/=" "!
)
for /f "tokens=3" %%i in (‘echo list volume ^| diskpart ^| findstr "磁盘分区"‘) do (
  set volume=%%i
  if %choose%==1 (
    echo.&echo ┃
    echo ┃正在查找^<!volume!^>盘下的^<!filter!^>文件...
    echo ┗━━━━━━━━━━━━━━━━━━━━━━━━━━━
    cd /d "!volume!:\"
    dir !filter! /s /b /a
  ) else if %choose%==2 (
    set subf=!filter!
    if not "!subf!"=="" (call :mode2 "!filter!") else echo -^>开始查找下一分区
  )
)
echo.&echo.
echo ┏━━━━━━━━━┓
echo ┃搜索完成！！      ┃
echo ┗━━━━━━━━━┛
rem 在set filter=后面和&符号之间不能有空格，无空格是把filter变量删除，有空格是赋予一个空格
echo 按任意键返回
pause>nul & set filter=& cls & goto choose

:mode2
rem %0为函数名称自身:mode2，%1为传过来的值,%~1为删除变量中的双引号"
set subf=%~1
rem 在此子搜索函数中把过滤器按照/符号分割开，并取得分割后的第一个的值
rem 再把分割后的剩下的值重赋予过滤器，并调用自身，直到过滤器为空为止，返回
for /f "tokens=1,* delims=/" %%j in ("%subf%") do (
  echo.&echo ┃
  echo ┃正在查找^<!volume!^>盘下的^<%%j^>文件...
  echo ┗━━━━━━━━━━━━━━━━━━━━━━━━━━━
  dir "!volume!:\""%%j" /s /b /a
  set subf=%%k
)
if not "!subf!"=="" (call %0 "!subf!")
goto :eof