标签：
在《Qt Quick 事件处理之信号与槽》中介绍了 QML 中怎样使用内建类型的信号以及怎样自己定义信号，这次我们来看看怎样处理鼠标、键盘、定时器等事件。这些时间在处理时，一般是通过信号来完毕的。
桌面开发的话，难免要处理鼠标事件……
看一个简单的处理鼠标事件的样例，先看代码（handle_mouse.qml）：
import QtQuick 2.0
import QtQuick.Controls 1.1
Rectangle {
width: 320;
height: 240;
MouseArea {
anchors.fill: parent;
acceptedButtons: Qt.LeftButton | Qt.RightButton;
onClicked: {
if(mouse.button == Qt.RightButton){
Qt.quit();
}
else if(mouse.button == Qt.LeftButton){
color = Qt.rgba((mouse.x % 255) / 255.0 , (mouse.y % 255) / 255.0, 0.6, 1.0);
}
}
onDoubleClicked: {
color = "gray";
}
}
}图 1 是刚执行时的效果：
图1 handle_mouse.qml 初始执行效果
图 2 是点击鼠标左键后的效果：
图 2 鼠标左键点击后的效果
假设你点一下鼠标右键。程序会退出。
演示样例简陋。但足以说明怎样处理鼠标事件，以下咱们慢慢来看。
MouseArea 对象能够附加到一个 item 上供 item 处理鼠标事件，它本身是一个不可见的 item 。在其内部，能够直接引用它所附着的对象的属性和方法。你能够将 MouseArea 理解为它所附着的 item 的代理。
MouseArea 有非常多属性， enabled 用来控制是否处理鼠标事件，默认值是 true ，假设你设置为 false ，那么它所代理的 item 就会无视鼠标事件。 acceptedButtons 属性设定接收拿些个鼠标按键产生的事件（左键、右键、中键），演示样例代码 "acceptedButtons: Qt.LeftButton | Qt.RightButton;" 表示处理鼠标左键和右键。
作为一个 item ， MouseArea 也拥有 anchors 属性。你能够使用它来描写叙述有效的鼠标区域。演示样例代码 "anchors.fill: parent;" 表示整个矩形区域都接受鼠标事件。
MouseArea 还有非常多其它属性，如 hoverEnabled ， pressed 等等。请參考 Qt 帮助文档。
演示样例代码中。在 MouseArea 对象内使用了 onClicked 和 onDoubleClicked 两个信号处理器，他们相应 MouseArea 的 onClicked 和 onDoubleClicked 信号。 MouseArea 还有非常多其它的信号。如 onPressed / onReleased / onEntered / onExited / onPressAndHold 等等，从名字上就能够看到这些信号的含义。
onClicked 信号的參数是 MouseEvent 类型，名为 mouse ，所以你能够在信号处理器中直接使用 mouse 来查询鼠标事件的详情。比方哪个 button 按下。正如演示样例代码中看到的那样， MouseEvent 的 button 属性保存了被按下的鼠标按键标记， x ， y 属性保存鼠标指针位置。另一个比較重要的属性 accepted ，假设你处理鼠标事件后不想这个事件再往下传递，就置其值为 true 。
onDoubleClicked 信号代表双击事件，其參数也是 MouseEvent 类型，演示样例中双击鼠标，矩形颜色变为灰色。
简单的鼠标事件处理就这些内容。依据你应用的须要，可能你还会处理 onPressed / onReleased / onEntered 等等信号。请參考 Qt 帮助。
手机上你可能较少处理键盘事件（有一个例外，BACK 按键），可是电脑上你免不了要响应键盘。
先看演示样例代码。handle_key.qml ：
import QtQuick 2.0
import QtQuick.Controls 1.1
Rectangle {
width: 320;
height: 480;
color: "gray";
focus: true;
Keys.enabled: true;
Keys.onEscapePressed: {
Qt.quit();
}
Keys.forwardTo: [moveText, likeQt];
Text {
id: moveText;
x: 20;
y: 20;
width: 200;
height: 30;
text: "Moving Text";
color: "blue";
//focus: true;
font { bold: true; pixelSize: 24;}
Keys.enabled: true;
Keys.onPressed: {
switch(event.key){
case Qt.Key_Left:
x -= 10;
break;
case Qt.Key_Right:
x += 10;
break;
case Qt.Key_Down:
y += 10;
break;
case Qt.Key_Up:
y -= 10;
break;
default:
return;
}
event.accepted = true;
}
}
CheckBox {
id: likeQt;
text: "Like Qt Quick";
anchors.left: parent.left;
anchors.leftMargin: 10;
anchors.bottom: parent.bottom;
anchors.bottomMargin: 10;
z: 1;
}
}
图 3 是初始执行效果图：
图 3 handle_key 初始效果
图 4 是我按了几次方向键，按了空格键后的效果：
图 4 移动文本，选中复选框
以下解释演示样例代码。介绍怎样使用 Keys 对象和信号处理器处理按键事件
事实上在 《Qt Quick 事件处理之信号与槽》、《Qt Quick 简单教程》和 《QML 语言基础》三篇文章中我们都有提到 Keys 对象，有的演示样例中也用到过，这里呢，我们专门介绍一下，力求使大家对 Keys 及按键处理有个较为全面的了解。
Keys 对象是 Qt Quick 提供的。专门供 Item 处理按键事件的对象。
它定义了非常多针对特定按键的信号，比方 onReturnPressed / onEscapePressed / onDownPressed / onDigit0Pressed / onBackPressed 等等；它还定义了更为普通的 onPressed 和 onReleased 信号，一般地。你能够使用这两个信号来处理大部分按键（请对比 Qt C++ 中的 keyPressEvent 和 keyReleaseEvent 来理解）。它们有一个名字是 event 的 KeyEvent 參数。包括了按键的具体信息。
KeyEvent 代表一个按键事件。假设一个按键被处理， event.accepted 应该被设置为 true 以免它被继续传递；要是你不设置它，那它可能会继续传递给其它的 item ，出现一些奇奇怪怪的问题。
Keys 有三个属性。
enabled 属性控制是否处理按键。
forwardTo 属性是列表类型，它表示传递按键事件给列表内的对象。假设某个对象 accept 了某个按键，那位列其后的对象就不会收到该按键事件。演示样例代码 "Keys.forwardTo: [moveText, likeQt];" 表明转发按键给 id 为 moveText 的 Text 对象和 id 为 likeQt 的 CheckBox 对象。
moveText 在前面，假设它消耗掉某个键。 likeQt 就收不到了。你能够改动 Text 对象的 Keys.onPressed 附加信号处理器。在 case 列表中加入 Qt.Key_Space 看看效果。
priority 属性同意你设置 Keys 附加属性的优先级。有两种，在 Item 之前处理按键，这是默认行为，在 Item 之后处理按键。
你能够对比着 Qt C++ 的 keyPressEvent() 函数来理解，假设你在派生类中重载了 keyPressEvent() 方法，那么你能够在重载方法的一開始调用父类的 keyPressEvent() 。也能够在你处理完感兴趣的事件后再调用父类的 keyPressEvent() 。这期间的逻辑关系也非常easy。假如 Keys 先处理按键，如它吃掉了某个键。它所依附的 Item 对象就收不到这个按键了；反之亦然。
Qt Quick 提供的一些元素本身会处理按键，比方演示样例中的 CheckBox ，它响应空格键来选中或取消选中。
而我们不须要给它附加 Keys 对象来再次处理按键事件。当然，假设你想改变它的按键响应逻辑，能够这么做。在解释 priority 属性时已经提到这点。
最后另一点要说明的是。假设你想某个元素处理按键，须要把焦点给它，这通过 Item 的 focus 属性来控制，置 true 就可以。
如今再来解释下演示样例代码。
Rectangle 对象的附加信号处理器 Keys.onEscapePressed 调用 Qt.quit() 退出，小白非常，不说了。
Text 对象实现了 Keys.onPressed 附加信号处理器，使用 switch-case 语句，分拣 event 參数的 key 属性。假设是上下左右四个键，就变更 Text 的位置。置 accepted 为 true 。声明这几个按键已名花有主找到归宿；否则就直接返回。给别人机会处理按键。你也看到了，正是由于这样。 CheckBox 才干拿到空格键来选中或取消复选框。
演示样例中的 CheckBox 对象定义时，没有专门处理按键，由于 Qt Quick 提供的实现已经处理了按键了。
嗯嗯，貌似内容非常少？走着。看定时器去。
定时器的作用还要说吗？好像有点儿啰嗦了呀。定时器么，就是周期性触发的一个事件，和寻经常使用的闹钟差点儿相同。你能够利用定时器来完毕一些周期性的任务，比方检查和server的连接呆死了没。比方备份用户数据……
在 QML 中， Timer 代表定时器。使用起来也非常easy，响应其 onTriggered() 信号就可以，它也就这么一个实用的信号。
另外它还有几个属性要说明一下， interval 指定定时周期，单位是毫秒，默认值是 1000 毫秒； repeat 设定定时器是周期性触发还是一次性触发，默认是一次性的（好像和 QTimer 不一样嗳）。running 属性。设置为 true 定时器就開始工作。设置为 false 就歇菜。默认是 false 。 triggeredOnStart 属性。怎么说呢， Qt 总是对我们这么好都有点儿那啥不好意思了，这个属性是考虑到有些同志的特殊需求。本来定时器启动后要等待设定的间隔才触发，假设你设置这个属性为 true ，那定时器開始执行时立刻先触发一次，默认值是 false 。
Timer 还有 start() / stop() / restart() 三个方法能够调用，它们会影响 running 属性，望文生义吧您。
如今来看一个简单的演示样例。倒计时。
世界杯倒计时按天算，山中一日世上千年，咱们这个演示样例用1秒顶它一天，倒数十秒。然后就开香槟庆祝下。
看代码（count_down.qml）：
import QtQuick 2.0
import QtQuick.Controls 1.1
Rectangle {
width: 320;
height: 240;
color: "gray";
QtObject{
id: attrs;
property int counter;
Component.onCompleted:{
attrs.counter = 10;
}
}
Text {
id: countShow;
anchors.centerIn: parent;
color: "blue";
font.pixelSize: 40;
}
Timer {
id: countDown;
interval: 1000;
repeat: true;
triggeredOnStart: true;
onTriggered:{
countShow.text = attrs.counter;
attrs.counter -= 1;
if(attrs.counter < 0)
{
countDown.stop();
countShow.text = "Clap Now!";
}
}
}
Button {
id: startButton;
anchors.top: countShow.bottom;
anchors.topMargin: 20;
anchors.horizontalCenter: countShow.horizontalCenter;
text: "Start";
onClicked: {
countDown.start();
}
}
}
计数保存在 QtObject 对象中， id 是 attrs 。在附加信号处理器 Component.onCompleted 中初始化 counter 属性的值为 10 。而在 Timer 对象的 onTriggered 信号处理器中递减 counter ，当 counter 为 0 时改动 Text 对象的文本为 "Clap Now!" 。
喏，就这么简单。
来看下效果。图 5 是初始效果：
图 5 倒计时程序初始效果
图 6 是计时效果：
图 6 计时
图 7 是倒计时结束的效果：
图 7 倒计时结束
假设你使用 qmlscene 执行 countdown.qml 文档，可能会发现它有一个 BUG 哦， "Start" 按钮第一次点击能够正常倒数计时。完了下次就不行了……我已经找到问题所在，不过还是留给你解决吧。
回想一下。温故知新：
版权声明：本文博客原创文章。博客，未经同意，不得转载。
标签：
原文地址：http://www.cnblogs.com/hrhguanli/p/4732582.html
